source: mainline/uspace/lib/libc/arch/ia64/_link.ld.in@ 2664838b

STARTUP(LIBC_PREFIX/arch/ARCH/src/entry.o)
ENTRY(__entry)

PHDRS {
        text PT_LOAD FLAGS(5);
        data PT_LOAD FLAGS(6);
}

SECTIONS {
        . = 0x4000;

        .init ALIGN(0x4000): SUBALIGN(0x4000) {
                *(.init);
        } : text
        .text : {
                *(.text);
                *(.rodata*);
        } :text

        .got ALIGN(0x4000) : SUBALIGN(0x4000) {
                _gp = .;
                *(.got*);
        } :data 
        .data : {
                *(.opd);
                *(.data .data.*);
                *(.sdata);
        } :data
        .tdata : {
                _tdata_start = .;
                *(.tdata);
                _tdata_end = .;
        } :data
        .tbss : {
                _tbss_start = .;
                *(.tbss);
                _tbss_end = .;
        } :data
        _tls_alignment = MAX(ALIGNOF(.tdata), ALIGNOF(.tbss));
        .bss : {
                *(.sbss);
                *(.scommon);
                *(COMMON);
                *(.bss);
        } :data

        . = ALIGN(0x4000);
        _heap = .;
 
        /DISCARD/ : {
                *(*);
        }
}