source: mainline/uspace/lib/c/arch/mips64/_link.ld.in@ d6cd626

OUTPUT_FORMAT(elf64-tradlittlemips)
STARTUP(LIBC_PATH/arch/UARCH/src/entry.o)
ENTRY(__entry)

PHDRS {
#ifdef LOADER
        interp PT_INTERP;
        text PT_LOAD FILEHDR PHDRS FLAGS(5);
#else
        text PT_LOAD FLAGS(5);
#endif
        data PT_LOAD FLAGS(6);
}

SECTIONS {
#ifdef LOADER
        . = 0x70004000 + SIZEOF_HEADERS;
        
        .interp : {
                *(.interp);
        } :interp :text
#else
        . = 0x4000 + SIZEOF_HEADERS;
#endif
        
        /* Make sure the code is aligned reasonably */
        . = ALIGN(., 16);
        
        .init : {
                *(.init);
        } :text
        
        .text : {
                *(.text .text.*);
                *(.rodata .rodata.*);
        } :text
        
        . = . + 0x4000;
        
        .data : {
                *(.data);
                *(.data.rel*);
        } :data
        
        .got : {
                _gp = .;
                *(.got);
        } :data
        
        .tdata : {
                _tdata_start = .;
                *(.tdata);
                _tdata_end = .;
        } :data
        
        .tbss : {
                _tbss_start = .;
                *(.tbss);
                _tbss_end = .;
        } :data
        
        _tls_alignment = MAX(ALIGNOF(.tdata), ALIGNOF(.tbss));
        
        .sbss : {
                *(.scommon);
                *(.sbss);
        }
        
        .bss : {
                *(.bss);
                *(COMMON);
        } :data
        
        /DISCARD/ : {
                *(*);
        }
}