source: mainline/uspace/lib/c/arch/arm64/src/fibril.S@ 9242ad9

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 9242ad9 was 84176f3, checked in by Jakub Jermář <jakub@…>, 7 years ago

arm64: Add support for the architecture

This changeset adds basic support to run HelenOS on AArch64, targeting
the QEMU virt platform.

Boot:

  • Boot relies on the EDK II firmware, GRUB2 for EFI and the HelenOS bootloader (UEFI application). EDK II loads GRUB2 from a CD, GRUB2 loads the HelenOS bootloader (via UEFI) which loads OS components.
  • UEFI applications use the PE/COFF format and must be relocatable. The first problem is solved by manually having the PE/COFF headers and tables written in assembler. The relocatable requirement is addressed by compiling the code with -fpic and having the bootloader relocate itself at its startup.

Kernel:

  • Kernel code for AArch64 consists mostly of stubbing out various architecture-specific hooks: virtual memory management, interrupt and exception handling, context switching (including FPU lazy switching), support for virtual timer, atomic sequences and barriers, cache and TLB maintenance, thread and process initialization.
  • The patch adds a kernel driver for GICv2 (interrupt controller).
  • The PL011 kernel driver is extended to allow userspace to take ownership of the console.
  • The current code is not able to dynamically obtain information about available devices on the underlying machine. The port instead implements a machine-func interface similar to the one implemented by arm32. It defines a machine for the QEMU AArch64 virt platform. The configuration (device addresses and IRQ numbers) is then baked into the machine definition.

User space:

  • Uspace code for AArch64 similarly mostly implements architecture-specific hooks: context saving/restoring, syscall support, TLS support.

The patchset allows to boot the system but user interaction with the OS
is not yet possible.
  • Property mode set to 100644
File size: 3.9 KB
Line 
1/*
2 * Copyright (c) 2015 Petr Pavlu
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *
9 * - Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * - Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 * - The name of the author may not be used to endorse or promote products
15 * derived from this software without specific prior written permission.
16 *
17 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27 */
28
29#include <abi/asmtool.h>
30#include <libarch/fibril_context.h>
31
32.text
33
34/* Static checks for the context_t save/load. */
35#if __CONTEXT_OFFSET_SP + 8 != __CONTEXT_OFFSET_PC
36#error sp and pc are not successive in context_t
37#endif
38#if __CONTEXT_OFFSET_X19 + 8 != __CONTEXT_OFFSET_X20
39#error x19 and x20 are not successive in context_t
40#endif
41#if __CONTEXT_OFFSET_X21 + 8 != __CONTEXT_OFFSET_X22
42#error x21 and x22 are not successive in context_t
43#endif
44#if __CONTEXT_OFFSET_X23 + 8 != __CONTEXT_OFFSET_X24
45#error x23 and x24 are not successive in context_t
46#endif
47#if __CONTEXT_OFFSET_X25 + 8 != __CONTEXT_OFFSET_X26
48#error x25 and x26 are not successive in context_t
49#endif
50#if __CONTEXT_OFFSET_X27 + 8 != __CONTEXT_OFFSET_X28
51#error x27 and x28 are not successive in context_t
52#endif
53#if __CONTEXT_OFFSET_X29 + 8 != __CONTEXT_OFFSET_TLS
54#error x29 and tls are not successive in context_t
55#endif
56
57FUNCTION_BEGIN(__context_save)
58 /* Save callee-saved registers into context_t pointed by x0. */
59 mov x1, sp
60 stp x1, x30, [x0, #__CONTEXT_OFFSET_SP]
61 stp x19, x20, [x0, #__CONTEXT_OFFSET_X19]
62 stp x21, x22, [x0, #__CONTEXT_OFFSET_X21]
63 stp x23, x24, [x0, #__CONTEXT_OFFSET_X23]
64 stp x25, x26, [x0, #__CONTEXT_OFFSET_X25]
65 stp x27, x28, [x0, #__CONTEXT_OFFSET_X27]
66 /* Save the last general-purpose register and TLS. */
67 mrs x1, tpidr_el0
68 stp x29, x1, [x0, #__CONTEXT_OFFSET_X29]
69 /* Save low 64 bits of v8-v15. */
70 stp d8, d9, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 0]
71 stp d10, d11, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 2]
72 stp d12, d13, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 4]
73 stp d14, d15, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 6]
74
75 /* Return 0. */
76 mov x0, #0
77 ret
78FUNCTION_END(__context_save)
79
80FUNCTION_BEGIN(__context_restore)
81 /* Restore callee-saved registers from context_t pointed by x0. */
82 ldp x2, x30, [x0, #__CONTEXT_OFFSET_SP]
83 mov sp, x2
84 ldp x19, x20, [x0, #__CONTEXT_OFFSET_X19]
85 ldp x21, x22, [x0, #__CONTEXT_OFFSET_X21]
86 ldp x23, x24, [x0, #__CONTEXT_OFFSET_X23]
87 ldp x25, x26, [x0, #__CONTEXT_OFFSET_X25]
88 ldp x27, x28, [x0, #__CONTEXT_OFFSET_X27]
89 /* Restore the last general-purpose register and TLS. */
90 ldp x29, x2, [x0, #__CONTEXT_OFFSET_X29]
91 msr tpidr_el0, x2
92 /* Restore low 64 bits of v8-v15. */
93 ldp d8, d9, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 0]
94 ldp d10, d11, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 2]
95 ldp d12, d13, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 4]
96 ldp d14, d15, [x0, #__CONTEXT_OFFSET_VREGS + 8 * 6]
97
98 /* Return the second argument. */
99 mov x0, x1
100 ret
101FUNCTION_END(__context_restore)
Note: See TracBrowser for help on using the repository browser.