source: mainline/kernel/arch/ia64/_link.ld.in@ 6688cc1

/** IA-64 linker script
 *
 *  It is ELF format, but its only section looks like this:
 *  kernel text
 *  kernel data
 *
 */

#define LOAD_ADDRESS_V  0xe000000004404000
#define LOAD_ADDRESS_P  0x0000000004404000

ENTRY(kernel_image_start)

SECTIONS {
        .image LOAD_ADDRESS_V: AT (LOAD_ADDRESS_P) {
                ktext_start = .;
                *(K_TEXT_START);
                *(.text)
                ktext_end = .;
                
                kdata_start = .;
                *(K_DATA_START)
                *(.rodata .rodata.*)
                *(.opd)
                *(.data .data.*)
                hardcoded_load_address = .;
                QUAD(LOAD_ADDRESS_V);
                hardcoded_ktext_size = .;
                QUAD(ktext_end - ktext_start);
                hardcoded_kdata_size = .;
                QUAD(kdata_end - kdata_start);
                *(.got .got.*)
                *(.sdata)
                *(.sbss)
                *(.scommon)
                *(.bss)
                *(COMMON);

                symbol_table = .;
                *(symtab.*);            /* Symbol table, must be LAST symbol!*/

                kdata_end = .;
        }

        /DISCARD/ : {
                *(*);
        }

}