source: mainline/kernel/arch/ia32/src/boot/boot.S@ 07bd231e

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 07bd231e was 7cb567cd, checked in by Martin Decky <martin@…>, 18 years ago

map kernel pages explicitly as writable (this solves compatibility issues with Intel Core 2)
make VESA framebuffer initialization more robust
  • Property mode set to 100644
File size: 10.2 KB
Line 
1#
2# Copyright (c) 2001-2004 Jakub Jermar
3# Copyright (c) 2005-2006 Martin Decky
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions
8# are met:
9#
10# - Redistributions of source code must retain the above copyright
11# notice, this list of conditions and the following disclaimer.
12# - Redistributions in binary form must reproduce the above copyright
13# notice, this list of conditions and the following disclaimer in the
14# documentation and/or other materials provided with the distribution.
15# - The name of the author may not be used to endorse or promote products
16# derived from this software without specific prior written permission.
17#
18# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29
30#include <arch/boot/boot.h>
31#include <arch/boot/memmap.h>
32#include <arch/mm/page.h>
33#include <arch/pm.h>
34
35#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
36
37.section K_TEXT_START, "ax"
38
39.code32
40.align 4
41.global multiboot_image_start
42multiboot_header:
43 .long MULTIBOOT_HEADER_MAGIC
44 .long MULTIBOOT_HEADER_FLAGS
45 .long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
46 .long multiboot_header
47 .long unmapped_ktext_start
48 .long 0
49 .long 0
50 .long multiboot_image_start
51
52multiboot_image_start:
53 movl $START_STACK, %esp # initialize stack pointer
54 lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register
55
56 movw $selector(KDATA_DES), %cx
57 movw %cx, %es
58 movw %cx, %fs
59 movw %cx, %gs
60 movw %cx, %ds # kernel data + stack
61 movw %cx, %ss
62
63 jmpl $selector(KTEXT_DES), $multiboot_meeting_point
64 multiboot_meeting_point:
65
66 movl %eax, grub_eax # save parameters from GRUB
67 movl %ebx, grub_ebx
68
69 xorl %eax, %eax
70 cpuid
71 cmp $0x0, %eax # any function > 0?
72 jbe pse_unsupported
73 movl $0x1, %eax # Basic function code 1
74 cpuid
75 bt $3, %edx # Test if PSE is supported
76 jc pse_supported
77
78 pse_unsupported:
79 movl $pse_msg, %esi
80 jmp error_halt
81
82 pse_supported:
83
84#ifdef CONFIG_FB
85 mov $vesa_init, %esi
86 mov $VESA_INIT_SEGMENT << 4, %edi
87 mov $e_vesa_init - vesa_init, %ecx
88 cld
89 rep movsb
90
91 mov $VESA_INIT_SEGMENT << 4, %edi
92 jmpl *%edi
93
94 vesa_meeting_point:
95
96 mov %esi, KA2PA(vesa_ph_addr)
97 mov %di, KA2PA(vesa_height)
98 shr $16, %edi
99 mov %di, KA2PA(vesa_width)
100 mov %bx, KA2PA(vesa_scanline)
101 shr $16, %ebx
102 mov %bx, KA2PA(vesa_bpp)
103#endif
104
105 call map_kernel # map kernel and turn paging on
106
107 movl grub_eax, %eax
108 movl grub_ebx, %ebx
109 cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
110 je valid_boot
111
112 xorl %ecx, %ecx # no memory size or map available
113 movl %ecx, e801memorysize
114 movl %ecx, e820counter
115
116 jmp invalid_boot
117
118 valid_boot:
119
120 movl (%ebx), %eax # ebx = physical address of struct multiboot_info
121
122 bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
123 jc mem_valid
124
125 xorl %ecx, %ecx
126 jmp mem_invalid
127
128 mem_valid:
129 movl 4(%ebx), %ecx # mbi->mem_lower
130 addl 8(%ebx), %ecx # mbi->mem_upper
131
132 mem_invalid:
133 movl %ecx, e801memorysize
134
135 bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
136 jc mods_valid
137
138 xorl %ecx, %ecx
139 movl %ecx, init
140 jmp mods_end
141
142 mods_valid:
143
144 movl 20(%ebx), %ecx # mbi->mods_count
145 movl %ecx, init
146
147 cmpl $0, %ecx
148 je mods_end
149
150 movl 24(%ebx), %esi # mbi->mods_addr
151 movl $init, %edi
152
153 mods_loop:
154
155 movl 0(%esi), %edx # mods->mod_start
156 addl $0x80000000, %edx
157 movl %edx, 4(%edi)
158
159 movl 4(%esi), %edx
160 subl 0(%esi), %edx # mods->mod_end - mods->mod_start
161 movl %edx, 8(%edi)
162
163 addl $16, %esi
164 addl $8 , %edi
165
166 loop mods_loop
167
168 mods_end:
169
170 bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
171 jc mmap_valid
172
173 xorl %edx, %edx
174 jmp mmap_invalid
175
176 mmap_valid:
177 movl 44(%ebx), %ecx # mbi->mmap_length
178 movl 48(%ebx), %esi # mbi->mmap_addr
179 movl $e820table, %edi
180 xorl %edx, %edx
181
182 mmap_loop:
183 cmpl $0, %ecx
184 jle mmap_end
185
186 movl 4(%esi), %eax # mmap->base_addr_low
187 movl %eax, (%edi)
188
189 movl 8(%esi), %eax # mmap->base_addr_high
190 movl %eax, 4(%edi)
191
192 movl 12(%esi), %eax # mmap->length_low
193 movl %eax, 8(%edi)
194
195 movl 16(%esi), %eax # mmap->length_high
196 movl %eax, 12(%edi)
197
198 movl 20(%esi), %eax # mmap->type
199 movl %eax, 16(%edi)
200
201 movl (%esi), %eax # mmap->size
202 addl $0x4, %eax
203 addl %eax, %esi
204 subl %eax, %ecx
205 addl $MEMMAP_E820_RECORD_SIZE, %edi
206 incl %edx
207 jmp mmap_loop
208
209 mmap_end:
210
211 mmap_invalid:
212 movl %edx, e820counter
213
214 invalid_boot:
215
216#ifdef CONFIG_SMP
217
218 # copy AP bootstrap routines below 1 MB
219
220 movl $BOOT_OFFSET, %esi
221 movl $AP_BOOT_OFFSET, %edi
222 movl $_hardcoded_unmapped_size, %ecx
223 cld
224 rep movsb
225
226#endif
227
228 call main_bsp # never returns
229
230 cli
231 hlt
232
233.global map_kernel
234map_kernel:
235 #
236 # Here we setup mapping for both the unmapped and mapped sections of the kernel.
237 # For simplicity, we map the entire 4G space.
238 #
239 movl %cr4, %ecx
240 orl $(1 << 4), %ecx # turn PSE on
241 andl $(~(1 << 5)), %ecx # turn PAE off
242 movl %ecx, %cr4
243
244 movl $(page_directory + 0), %esi
245 movl $(page_directory + 2048), %edi
246 xorl %ecx, %ecx
247 xorl %ebx, %ebx
2480:
249 movl $((1 << 7) | (1 << 1) | (1 << 0)), %eax
250 orl %ebx, %eax
251 movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
252 movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
253 addl $(4 * 1024 * 1024), %ebx
254
255 incl %ecx
256 cmpl $512, %ecx
257 jl 0b
258
259 movl %esi, %cr3
260
261 movl %cr0, %ebx
262 orl $(1 << 31), %ebx # turn paging on
263 movl %ebx, %cr0
264 ret
265
266# Print string from %esi to EGA display (in red) and halt
267error_halt:
268 movl $0xb8000, %edi # base of EGA text mode memory
269 xorl %eax, %eax
270
271 movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
272 movb $0xe, %al
273 outb %al, %dx
274
275 movw $0x3d5, %dx
276 inb %dx, %al
277 shl $8, %ax
278
279 movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
280 movb $0xf, %al
281 outb %al, %dx
282
283 movw $0x3d5, %dx
284 inb %dx, %al
285
286 cmp $1920, %ax
287 jbe cursor_ok
288 movw $1920, %ax # sanity check for the cursor on the last line
289 cursor_ok:
290
291 movw %ax, %bx
292 shl $1, %eax
293 addl %eax, %edi
294
295 movw $0x0c00, %ax # black background, light red foreground
296 cld
297
298 ploop:
299 lodsb
300 cmp $0, %al
301 je ploop_end
302 stosw
303 inc %bx
304 jmp ploop
305 ploop_end:
306
307 movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
308 movb $0xe, %al
309 outb %al, %dx
310
311 movw $0x3d5, %dx
312 movb %bh, %al
313 outb %al, %dx
314
315 movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
316 movb $0xf, %al
317 outb %al, %dx
318
319 movw $0x3d5, %dx
320 movb %bl, %al
321 outb %al, %dx
322
323 cli
324 hlt
325
326#ifdef CONFIG_FB
327vesa_init:
328 jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
329
330.code16
331vesa_init_real:
332
333 mov %cr0, %eax
334 and $~1, %eax
335 mov %eax, %cr0
336
337 jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
338
339vesa_init_real2:
340
341 mov $VESA_INIT_SEGMENT, %bx
342
343 mov %bx, %es
344 mov %bx, %fs
345 mov %bx, %gs
346 mov %bx, %ds
347 mov %bx, %ss
348
349 movl %esp, %eax
350 movl $0x0000fffc, %esp
351 movl $0x0000fffc, %ebp
352 pushl %eax
353
354#define VESA_INFO_SIZE 1024
355
356#define VESA_MODE_LIST_PTR_OFFSET 14
357#define VESA_MODE_WIDTH_OFFSET 18
358#define VESA_MODE_HEIGHT_OFFSET 20
359#define VESA_MODE_BPP_OFFSET 25
360#define VESA_MODE_SCANLINE_OFFSET 16
361#define VESA_MODE_PHADDR_OFFSET 40
362
363#define VESA_END_OF_MODES 0xffff
364
365#define VESA_OK 0x4f
366
367#define VESA_GET_INFO 0x4f00
368#define VESA_GET_MODE_INFO 0x4f01
369#define VESA_SET_MODE 0x4f02
370
371#define CONFIG_VESA_BPP_a 255
372
373#if CONFIG_VESA_BPP == 24
374#undef CONFIG_VESA_BPP_a
375#define CONFIG_VESA_BPP_a 32
376#endif
377
378 mov $VESA_GET_INFO, %ax
379 mov $e_vesa_init - vesa_init, %di
380 push %di
381 int $0x10
382
383 pop %di
384 cmp $VESA_OK, %al
385 jnz 0f
386
387 mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
388 mov %si, %gs
389 mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
390
391 add $VESA_INFO_SIZE, %di
392
3931:# Try next mode
394 mov %gs:(%si), %cx
395 cmp $VESA_END_OF_MODES, %cx
396 jz 0f
397
398 inc %si
399 inc %si
400 push %cx
401 push %di
402 push %si
403 mov $VESA_GET_MODE_INFO, %ax
404 int $0x10
405
406 pop %si
407 pop %di
408 pop %cx
409 cmp $VESA_OK, %al
410 jnz 0f
411
412 mov $CONFIG_VESA_WIDTH, %ax
413 cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
414 jnz 1b
415
416 mov $CONFIG_VESA_HEIGHT,%ax
417 cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
418 jnz 1b
419
420 mov $CONFIG_VESA_BPP, %al
421 cmp VESA_MODE_BPP_OFFSET(%di), %al
422 jz 2f
423
424 mov $CONFIG_VESA_BPP_a, %al
425 cmp VESA_MODE_BPP_OFFSET(%di), %al
426 jnz 1b
427
4282:
429
430 mov %cx, %bx
431 or $0xc000, %bx
432 push %di
433 mov $VESA_SET_MODE, %ax
434 int $0x10
435
436 pop %di
437 cmp $VESA_OK, %al
438 jnz 0f
439
440 mov VESA_MODE_PHADDR_OFFSET(%di), %esi
441 mov VESA_MODE_WIDTH_OFFSET(%di), %ax
442 shl $16, %eax
443 mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
444 mov VESA_MODE_BPP_OFFSET(%di), %bl
445 xor %bh, %bh
446 shl $16, %ebx
447 mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
448 mov %eax, %edi
449
4508:
451
452 mov %cr0, %eax
453 or $1, %eax
454 mov %eax, %cr0
455
456 jmp 9f
4579:
458
459 ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
460
4610:# No prefered mode found
462 mov $0x111, %cx
463 push %di
464 push %cx
465 mov $VESA_GET_MODE_INFO, %ax
466 int $0x10
467
468 pop %cx
469 pop %di
470 cmp $VESA_OK, %al
471 jnz 1f
472 jz 2b # Force relative jump
473
4741:
475 mov $0x0003, %ax
476 int $0x10
477 mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
478 xor %ax, %ax
479 jz 8b # Force relative jump
480
481
482.code32
483vesa_init_protect:
484 movw $selector(KDATA_DES), %cx
485 movw %cx, %es
486 movw %cx, %fs
487 movw %cx, %gs
488 movw %cx, %ds # kernel data + stack
489 movw %cx, %ss
490
491 movl $START_STACK, %esp # initialize stack pointer
492
493 jmpl $selector(KTEXT_DES), $vesa_meeting_point
494
495.align 4
496e_vesa_init:
497#endif
498
499.section K_DATA_START, "aw", @progbits
500
501.align 4096
502page_directory:
503 .space 4096, 0
504
505grub_eax:
506 .long 0
507
508grub_ebx:
509 .long 0
510
511pse_msg:
512 .ascii "Page Size Extension not supported. System halted.\0"
Note: See TracBrowser for help on using the repository browser.