source: mainline/kernel/arch/ia32/_link.ld.in@ ff50f40

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since ff50f40 was b3f8fb7, checked in by Martin Decky <martin@…>, 19 years ago

huge type system cleanup
remove cyclical type dependencies across multiple header files
many minor coding style fixes
  • Property mode set to 100644
File size: 1.6 KB
Line 
1/** IA-32 linker script
2 *
3 * umapped section:
4 * kernel text
5 * kernel data
6 * mapped section:
7 * kernel text
8 * kernel data
9 */
10
11#include <arch/boot/boot.h>
12#include <arch/mm/page.h>
13
14SECTIONS {
15 .unmapped BOOT_OFFSET: AT (0) {
16 unmapped_ktext_start = .;
17 *(K_TEXT_START);
18 unmapped_ktext_end = .;
19
20 unmapped_kdata_start = .;
21 *(K_DATA_START);
22 unmapped_kdata_end = .;
23 }
24
25 .mapped (PA2KA(BOOT_OFFSET)+SIZEOF(.unmapped)): AT (SIZEOF(.unmapped)) {
26 ktext_start = .;
27 *(.text);
28 ktext_end = .;
29
30 kdata_start = .;
31 *(.data); /* initialized data */
32 *(.rodata*); /* string literals */
33 *(COMMON); /* global variables */
34 hardcoded_load_address = .;
35 LONG(PA2KA(BOOT_OFFSET));
36 hardcoded_ktext_size = .;
37 LONG((ktext_end - ktext_start) + (unmapped_ktext_end - unmapped_ktext_start));
38 hardcoded_kdata_size = .;
39 LONG((kdata_end - kdata_start) + (unmapped_kdata_end - unmapped_kdata_start));
40 hardcoded_unmapped_ktext_size = .;
41 LONG(unmapped_ktext_end - unmapped_ktext_start);
42 hardcoded_unmapped_kdata_size = .;
43 LONG(unmapped_kdata_end - unmapped_kdata_start);
44 symbol_table = .;
45 *(symtab.*); /* Symbol table, must be LAST symbol! */
46 *(.bss); /* uninitialized static variables */
47 kdata_end = .;
48 }
49
50 /DISCARD/ : {
51 *(.note.GNU-stack);
52 *(.comment);
53 }
54
55#ifdef CONFIG_SMP
56
57 _hardcoded_unmapped_size = (unmapped_ktext_end - unmapped_ktext_start) + (unmapped_kdata_end - unmapped_kdata_start);
58 ap_boot = unmapped_ap_boot - BOOT_OFFSET + AP_BOOT_OFFSET;
59 ap_gdtr = unmapped_ap_gdtr - BOOT_OFFSET + AP_BOOT_OFFSET;
60 protected_ap_gdtr = PA2KA(ap_gdtr);
61
62#endif /* CONFIG_SMP */
63
64}
Note: See TracBrowser for help on using the repository browser.