Context Navigation

multiboot.S@ 1f5c9c96

Visit:

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export

Last change on this file since 1f5c9c96 was 1f5c9c96, checked in by Martin Decky <martin@…>, 14 years ago

implement multiboot v2 specification and use it in GRUB for UEFI

improve multiboot v1 code, move defines to a common location
rename VESA framebuffer stuff to generic "boot framebuffer"
small collateral changes

Property mode set to 100644

File size: 14.0 KB

Rev	Line
[873c681]	1	/*
	2	* Copyright (c) 2005 Ondrej Palkovsky
	3	* Copyright (c) 2006 Martin Decky
	4	* Copyright (c) 2008 Jakub Jermar
	5	* All rights reserved.
	6	*
	7	* Redistribution and use in source and binary forms, with or without
	8	* modification, are permitted provided that the following conditions
	9	* are met:
	10	*
	11	* - Redistributions of source code must retain the above copyright
	12	* notice, this list of conditions and the following disclaimer.
	13	* - Redistributions in binary form must reproduce the above copyright
	14	* notice, this list of conditions and the following disclaimer in the
	15	* documentation and/or other materials provided with the distribution.
	16	* - The name of the author may not be used to endorse or promote products
	17	* derived from this software without specific prior written permission.
	18	*
	19	* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
	20	* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
	21	* OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
	22	* IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
	23	* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
	24	* NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
	25	* DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
	26	* THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
	27	* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
	28	* THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
	29	*/
[1141c1a]	30
[46d26ee]	31	#include <arch/boot/boot.h>
[a1f60f3]	32	#include <arch/mm/page.h>
[6f878b7]	33	#include <arch/mm/ptl.h>
[8fc0d455]	34	#include <arch/pm.h>
[1f5c9c96]	35	#include <genarch/multiboot/multiboot.h>
[c4b3e3e]	36	#include <arch/cpuid.h>
[1f5c9c96]	37	#include <arch/cpu.h>
[1141c1a]	38
[873c681]	39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
[421c833]	40
[874e312a]	41	.section K_TEXT_START, "ax"
[46d26ee]	42
[8ccec3c1]	43	.code32
[873c681]	44
	45	.macro pm_error msg
	46	movl \msg, %esi
	47	jmp pm_error_halt
	48	.endm
	49
	50	.macro pm_status msg
	51	#ifdef CONFIG_EGA
	52	pushl %esi
	53	movl \msg, %esi
	54	call pm_early_puts
	55	popl %esi
	56	#endif
	57	.endm
	58
	59	.macro pm2_status msg
	60	#ifndef CONFIG_FB
	61	pm_status \msg
	62	#endif
	63	.endm
	64
[8ccec3c1]	65	.align 4
[46d26ee]	66	.global multiboot_image_start
[8ccec3c1]	67	multiboot_header:
	68	.long MULTIBOOT_HEADER_MAGIC
	69	.long MULTIBOOT_HEADER_FLAGS
[873c681]	70	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) /* checksum */
[8725fb4]	71	.long multiboot_header
	72	.long unmapped_ktext_start
[8ccec3c1]	73	.long 0
	74	.long 0
[8725fb4]	75	.long multiboot_image_start
[8ccec3c1]	76
	77	multiboot_image_start:
[e13daa5d]	78	cld
[421c833]	79
[873c681]	80	/* Initialize stack pointer */
	81	movl $START_STACK, %esp
	82
	83	/* Initialize Global Descriptor Table register */
	84	lgdtl bootstrap_gdtr
	85
	86	/* Kernel data + stack */
[1d3d2cf]	87	movw $GDT_SELECTOR(KDATA_DES), %cx
[1a67595]	88	movw %cx, %es
[873c681]	89	movw %cx, %ds
[1a67595]	90	movw %cx, %ss
[421c833]	91
[873c681]	92	/*
	93	* Simics seems to remove hidden part of GS on entering user mode
	94	* when _visible_ part of GS does not point to user-mode segment.
	95	*/
[1d3d2cf]	96	movw $GDT_SELECTOR(UDATA_DES), %cx
[65640fef]	97	movw %cx, %fs
	98	movw %cx, %gs
[1a67595]	99
[1d3d2cf]	100	jmpl $GDT_SELECTOR(KTEXT32_DES), $multiboot_meeting_point
[1a67595]	101	multiboot_meeting_point:
	102
[1f5c9c96]	103	/*
	104	* Protected 32-bit. We want to reuse the code-seg descriptor,
	105	* the Default operand size must not be 1 when entering long mode.
	106	*/
	107
	108	/* Save multiboot arguments */
	109	movl %eax, multiboot_eax
	110	movl %ebx, multiboot_ebx
[46d26ee]	111
[873c681]	112	pm_status $status_prot
[ac88c93]	113
[421c833]	114	movl $(INTEL_CPUID_EXTENDED), %eax
	115	cpuid
	116	cmp $(INTEL_CPUID_EXTENDED), %eax
[4fb6bf36]	117	ja extended_cpuid_supported
[421c833]	118
[873c681]	119	pm_error $err_extended_cpuid
[4fb6bf36]	120
	121	extended_cpuid_supported:
	122
	123	movl $(AMD_CPUID_EXTENDED), %eax
[ac88c93]	124	cpuid
[4fb6bf36]	125	bt $(AMD_EXT_LONG_MODE), %edx
[421c833]	126	jc long_mode_supported
	127
[873c681]	128	pm_error $err_long_mode
[421c833]	129
[ac88c93]	130	long_mode_supported:
	131
[4fb6bf36]	132	bt $(AMD_EXT_NOEXECUTE), %edx
	133	jc noexecute_supported
	134
[873c681]	135	pm_error $err_noexecute
[4fb6bf36]	136
	137	noexecute_supported:
	138
	139	movl $(INTEL_CPUID_STANDARD), %eax
	140	cpuid
	141	bt $(INTEL_FXSAVE), %edx
[421c833]	142	jc fx_supported
[4fb6bf36]	143
[873c681]	144	pm_error $err_fx
[4fb6bf36]	145
	146	fx_supported:
	147
	148	bt $(INTEL_SSE2), %edx
[421c833]	149	jc sse2_supported
[4fb6bf36]	150
[873c681]	151	pm_error $err_sse2
[4fb6bf36]	152
	153	sse2_supported:
[873c681]	154
[421c833]	155	#include "vesa_prot.inc"
[873c681]	156
	157	pm2_status $status_prot2
	158
	159	/*
	160	* Enable 64-bit page translation entries - CR4.PAE = 1.
	161	* Paging is not enabled until after long mode is enabled.
	162	*/
[8725fb4]	163
[6f878b7]	164	movl %cr4, %eax
	165	btsl $5, %eax
	166	movl %eax, %cr4
[421c833]	167
[873c681]	168	/* Set up paging tables */
[6f878b7]	169	leal ptl_0, %eax
	170	movl %eax, %cr3
[c4b3e3e]	171
[873c681]	172	/* Enable long mode */
	173	movl $EFER_MSR_NUM, %ecx
	174	rdmsr /* read EFER */
	175	btsl $AMD_LME_FLAG, %eax /* set LME = 1 */
	176	wrmsr
[8725fb4]	177
[873c681]	178	/* Enable paging to activate long mode (set CR0.PG = 1) */
[6f878b7]	179	movl %cr0, %eax
	180	btsl $31, %eax
	181	movl %eax, %cr0
[c245372b]	182
[873c681]	183	/* At this point we are in compatibility mode */
[1d3d2cf]	184	jmpl $GDT_SELECTOR(KTEXT_DES), $start64
[c245372b]	185
[873c681]	186	/** Print string to EGA display (in light red) and halt.
	187	*
	188	* Should be executed from 32 bit protected mode with paging
	189	* turned off. Stack is not required. This routine is used even
	190	* if CONFIG_EGA is not enabled. Since we are going to halt the
	191	* CPU anyway, it is always better to at least try to print
	192	* some hints.
	193	*
[da52547]	194	* @param %esi Pointer to the NULL-terminated string
	195	* to be print.
[873c681]	196	*
	197	*/
	198	pm_error_halt:
	199	movl $0xb8000, %edi /* base of EGA text mode memory */
	200	xorl %eax, %eax
	201
	202	/* Read bits 8 - 15 of the cursor address */
	203	movw $0x3d4, %dx
	204	movb $0xe, %al
	205	outb %al, %dx
	206
	207	movw $0x3d5, %dx
	208	inb %dx, %al
	209	shl $8, %ax
	210
	211	/* Read bits 0 - 7 of the cursor address */
	212	movw $0x3d4, %dx
	213	movb $0xf, %al
	214	outb %al, %dx
	215
	216	movw $0x3d5, %dx
	217	inb %dx, %al
	218
	219	/* Sanity check for the cursor on screen */
	220	cmp $2000, %ax
	221	jb err_cursor_ok
	222
	223	movw $1998, %ax
	224
	225	err_cursor_ok:
	226
	227	movw %ax, %bx
	228	shl $1, %eax
	229	addl %eax, %edi
	230
	231	err_ploop:
	232	lodsb
	233
	234	cmp $0, %al
	235	je err_ploop_end
	236
	237	movb $0x0c, %ah /* black background, light red foreground */
	238	stosw
	239
	240	/* Sanity check for the cursor on the last line */
	241	inc %bx
	242	cmp $2000, %bx
	243	jb err_ploop
	244
	245	/* Scroll the screen (24 rows) */
	246	movl %esi, %edx
	247	movl $0xb80a0, %esi
	248	movl $0xb8000, %edi
[22c3444]	249	movl $960, %ecx
	250	rep movsl
[873c681]	251
	252	/* Clear the 24th row */
	253	xorl %eax, %eax
[22c3444]	254	movl $40, %ecx
	255	rep stosl
[873c681]	256
	257	/* Go to row 24 */
	258	movl %edx, %esi
	259	movl $0xb8f00, %edi
	260	movw $1920, %bx
	261
	262	jmp err_ploop
	263	err_ploop_end:
	264
	265	/* Write bits 8 - 15 of the cursor address */
	266	movw $0x3d4, %dx
	267	movb $0xe, %al
	268	outb %al, %dx
	269
	270	movw $0x3d5, %dx
	271	movb %bh, %al
	272	outb %al, %dx
	273
	274	/* Write bits 0 - 7 of the cursor address */
	275	movw $0x3d4, %dx
	276	movb $0xf, %al
	277	outb %al, %dx
	278
	279	movw $0x3d5, %dx
	280	movb %bl, %al
	281	outb %al, %dx
	282
	283	cli
	284	hlt1:
	285	hlt
	286	jmp hlt1
	287
	288	/** Print string to EGA display (in light green).
	289	*
	290	* Should be called from 32 bit protected mode with paging
	291	* turned off. A stack space of at least 24 bytes is required,
	292	* but the function does not establish a stack frame.
	293	*
	294	* Macros such as pm_status and pm2_status take care that
	295	* this function is used only when CONFIG_EGA is enabled
	296	* and CONFIG_FB is disabled.
	297	*
[da52547]	298	* @param %esi Pointer to the NULL-terminated string
	299	* to be print.
[873c681]	300	*
	301	*/
	302	pm_early_puts:
	303	pushl %eax
	304	pushl %ebx
	305	pushl %ecx
	306	pushl %edx
	307	pushl %edi
	308
	309	movl $0xb8000, %edi /* base of EGA text mode memory */
	310	xorl %eax, %eax
	311
	312	/* Read bits 8 - 15 of the cursor address */
	313	movw $0x3d4, %dx
	314	movb $0xe, %al
	315	outb %al, %dx
	316
	317	movw $0x3d5, %dx
	318	inb %dx, %al
	319	shl $8, %ax
	320
	321	/* Read bits 0 - 7 of the cursor address */
	322	movw $0x3d4, %dx
	323	movb $0xf, %al
	324	outb %al, %dx
	325
	326	movw $0x3d5, %dx
	327	inb %dx, %al
	328
	329	/* Sanity check for the cursor on screen */
	330	cmp $2000, %ax
	331	jb pm_puts_cursor_ok
	332
	333	movw $1998, %ax
	334
	335	pm_puts_cursor_ok:
	336
	337	movw %ax, %bx
	338	shl $1, %eax
	339	addl %eax, %edi
	340
	341	pm_puts_ploop:
	342	lodsb
	343
	344	cmp $0, %al
	345	je pm_puts_ploop_end
	346
	347	movb $0x0a, %ah /* black background, light green foreground */
	348	stosw
	349
	350	/* Sanity check for the cursor on the last line */
	351	inc %bx
	352	cmp $2000, %bx
	353	jb pm_puts_ploop
	354
	355	/* Scroll the screen (24 rows) */
	356	movl %esi, %edx
	357	movl $0xb80a0, %esi
	358	movl $0xb8000, %edi
[22c3444]	359	movl $960, %ecx
	360	rep movsl
[873c681]	361
	362	/* Clear the 24th row */
	363	xorl %eax, %eax
[22c3444]	364	movl $40, %ecx
	365	rep stosl
[873c681]	366
	367	/* Go to row 24 */
	368	movl %edx, %esi
	369	movl $0xb8f00, %edi
	370	movw $1920, %bx
	371
	372	jmp pm_puts_ploop
	373	pm_puts_ploop_end:
	374
	375	/* Write bits 8 - 15 of the cursor address */
	376	movw $0x3d4, %dx
	377	movb $0xe, %al
	378	outb %al, %dx
	379
	380	movw $0x3d5, %dx
	381	movb %bh, %al
	382	outb %al, %dx
	383
	384	/* Write bits 0 - 7 of the cursor address */
	385	movw $0x3d4, %dx
	386	movb $0xf, %al
	387	outb %al, %dx
	388
	389	movw $0x3d5, %dx
	390	movb %bl, %al
	391	outb %al, %dx
	392
	393	popl %edi
	394	popl %edx
	395	popl %ecx
	396	popl %ebx
	397	popl %eax
	398
	399	ret
	400
[6f878b7]	401	.code64
[873c681]	402
	403	.macro long_status msg
	404	pushq %rdi
	405	movq \msg, %rdi
	406	call early_puts
	407	popq %rdi
	408	.endm
	409
[6f878b7]	410	start64:
[873c681]	411
	412	/*
	413	* Long mode.
	414	*/
	415
[c4b3e3e]	416	movq $(PA2KA(START_STACK)), %rsp
[421c833]	417
[873c681]	418	/* Create the first stack frame */
	419	pushq $0
	420	movq %rsp, %rbp
	421
	422	long_status $status_long
	423
[1f5c9c96]	424	/* Call arch_pre_main(multiboot_eax, multiboot_ebx) */
[5d8d71e]	425	xorq %rdi, %rdi
[1f5c9c96]	426	movl multiboot_eax, %edi
[5d8d71e]	427	xorq %rsi, %rsi
[1f5c9c96]	428	movl multiboot_ebx, %esi
[a1f60f3]	429
	430	movabsq $arch_pre_main, %rax
	431	callq *%rax
[8778271]	432
[873c681]	433	long_status $status_main
[a1f60f3]	434
[873c681]	435	/* Call main_bsp() */
[a1f60f3]	436	movabsq $main_bsp, %rax
	437	call *%rax
[7cb567cd]	438
[873c681]	439	/* Not reached */
[421c833]	440	cli
	441	hlt0:
	442	hlt
	443	jmp hlt0
[ac88c93]	444
[873c681]	445	/** Print string to EGA display.
	446	*
	447	* Should be called from long mode (with paging enabled
	448	* and stack established). This function is ABI compliant
	449	* (without red-zone).
	450	*
	451	* If CONFIG_EGA is undefined or CONFIG_FB is defined
	452	* then this function does nothing.
	453	*
[da52547]	454	* @param %rdi Pointer to the NULL-terminated string
	455	* to be printed.
[873c681]	456	*
	457	*/
	458	early_puts:
	459
	460	#if ((defined(CONFIG_EGA)) && (!defined(CONFIG_FB)))
	461
	462	/* Prologue, save preserved registers */
	463	pushq %rbp
	464	movq %rsp, %rbp
	465	pushq %rbx
[ac88c93]	466
[873c681]	467	movq %rdi, %rsi
	468	movq $(PA2KA(0xb8000)), %rdi /* base of EGA text mode memory */
	469	xorq %rax, %rax
	470
	471	/* Read bits 8 - 15 of the cursor address */
	472	movw $0x3d4, %dx
[ac88c93]	473	movb $0xe, %al
	474	outb %al, %dx
	475
	476	movw $0x3d5, %dx
	477	inb %dx, %al
	478	shl $8, %ax
	479
[873c681]	480	/* Read bits 0 - 7 of the cursor address */
	481	movw $0x3d4, %dx
[ac88c93]	482	movb $0xf, %al
	483	outb %al, %dx
	484
	485	movw $0x3d5, %dx
	486	inb %dx, %al
	487
[873c681]	488	/* Sanity check for the cursor on screen */
	489	cmp $2000, %ax
	490	jb early_puts_cursor_ok
[421c833]	491
[873c681]	492	movw $1998, %ax
[421c833]	493
[873c681]	494	early_puts_cursor_ok:
[ac88c93]	495
	496	movw %ax, %bx
[873c681]	497	shl $1, %rax
	498	addq %rax, %rdi
[ac88c93]	499
[873c681]	500	early_puts_ploop:
[ac88c93]	501	lodsb
[873c681]	502
[ac88c93]	503	cmp $0, %al
[873c681]	504	je early_puts_ploop_end
	505
	506	movb $0x0e, %ah /* black background, yellow foreground */
[ac88c93]	507	stosw
[873c681]	508
	509	/* Sanity check for the cursor on the last line */
[421c833]	510	inc %bx
[873c681]	511	cmp $2000, %bx
	512	jb early_puts_ploop
	513
	514	/* Scroll the screen (24 rows) */
	515	movq %rsi, %rdx
	516	movq $(PA2KA(0xb80a0)), %rsi
	517	movq $(PA2KA(0xb8000)), %rdi
[e80329d6]	518	movl $480, %ecx
[22c3444]	519	rep movsq
[873c681]	520
	521	/* Clear the 24th row */
[e80329d6]	522	xorl %eax, %eax
	523	movl $20, %ecx
[22c3444]	524	rep stosq
[873c681]	525
	526	/* Go to row 24 */
	527	movq %rdx, %rsi
	528	movq $(PA2KA(0xb8f00)), %rdi
	529	movw $1920, %bx
	530
	531	jmp early_puts_ploop
	532	early_puts_ploop_end:
	533
	534	/* Write bits 8 - 15 of the cursor address */
	535	movw $0x3d4, %dx
[ac88c93]	536	movb $0xe, %al
	537	outb %al, %dx
	538
	539	movw $0x3d5, %dx
	540	movb %bh, %al
	541	outb %al, %dx
	542
[873c681]	543	/* Write bits 0 - 7 of the cursor address */
	544	movw $0x3d4, %dx
[ac88c93]	545	movb $0xf, %al
	546	outb %al, %dx
	547
	548	movw $0x3d5, %dx
	549	movb %bl, %al
	550	outb %al, %dx
[421c833]	551
[873c681]	552	/* Epilogue, restore preserved registers */
	553	popq %rbx
	554	leave
	555
	556	#endif
	557
	558	ret
[421c833]	559
	560	#include "vesa_real.inc"
[19077a5]	561
	562	.section K_INI_PTLS, "aw", @progbits
	563
[873c681]	564	/** Generate initial page table contents.
	565	*
	566	* @param cnt Number of entries to generate. Must be multiple of 8.
	567	* @param g Number of GB that will be added to the mapping.
	568	*
	569	*/
[a1f60f3]	570	.macro ptl2gen cnt g
[64f6ef04]	571	.if \cnt
	572	ptl2gen "\cnt - 8" \g
	573	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	574	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	575	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	576	.quad ((\cnt - 5) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	577	.quad ((\cnt - 4) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	578	.quad ((\cnt - 3) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	579	.quad ((\cnt - 2) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	580	.quad ((\cnt - 1) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
	581	.endif
[19077a5]	582	.endm
	583
[873c681]	584	/* Page table for pages in the 1st gigabyte. */
[1141c1a]	585	.align 4096
[a1f60f3]	586	ptl_2_0g:
[19077a5]	587	ptl2gen 512 0
	588
[873c681]	589	/* Page table for pages in the 2nd gigabyte. */
[19077a5]	590	.align 4096
	591	ptl_2_1g:
	592	ptl2gen 512 1
	593
[873c681]	594	/* Page table for pages in the 3rd gigabyte. */
[19077a5]	595	.align 4096
	596	ptl_2_2g:
	597	ptl2gen 512 2
	598
[873c681]	599	/* Page table for pages in the 4th gigabyte. */
[19077a5]	600	.align 4096
	601	ptl_2_3g:
	602	ptl2gen 512 3
[b9e97fb]	603
[873c681]	604	/* Page table for pages in the 5th gigabyte. */
[64f6ef04]	605	.align 4096
	606	ptl_2_4g:
[fef504a]	607	ptl2gen 512 4
[64f6ef04]	608
[873c681]	609	/* Page table for pages in the 6th gigabyte. */
[64f6ef04]	610	.align 4096
	611	ptl_2_5g:
[fef504a]	612	ptl2gen 512 5
[64f6ef04]	613
[873c681]	614	/* Page table for pages in the 7th gigabyte. */
[64f6ef04]	615	.align 4096
	616	ptl_2_6g:
[fef504a]	617	ptl2gen 512 6
[64f6ef04]	618
[873c681]	619	/* Page table for pages in the 8th gigabyte. */
[64f6ef04]	620	.align 4096
	621	ptl_2_7g:
[fef504a]	622	ptl2gen 512 7
[64f6ef04]	623
[6f878b7]	624	.align 4096
	625	ptl_1:
[873c681]	626	/* Identity mapping for [0; 8G) */
[19077a5]	627	.quad ptl_2_0g + (PTL_WRITABLE \| PTL_PRESENT)
[a1f60f3]	628	.quad ptl_2_1g + (PTL_WRITABLE \| PTL_PRESENT)
[19077a5]	629	.quad ptl_2_2g + (PTL_WRITABLE \| PTL_PRESENT)
	630	.quad ptl_2_3g + (PTL_WRITABLE \| PTL_PRESENT)
[64f6ef04]	631	.quad ptl_2_4g + (PTL_WRITABLE \| PTL_PRESENT)
	632	.quad ptl_2_5g + (PTL_WRITABLE \| PTL_PRESENT)
	633	.quad ptl_2_6g + (PTL_WRITABLE \| PTL_PRESENT)
	634	.quad ptl_2_7g + (PTL_WRITABLE \| PTL_PRESENT)
	635	.fill 504, 8, 0
[421c833]	636
[6f878b7]	637	.align 4096
	638	.global ptl_0
	639	ptl_0:
	640	.quad ptl_1 + (PTL_WRITABLE \| PTL_PRESENT)
[a1f60f3]	641	.fill 255, 8, 0
[6f878b7]	642	.quad ptl_1 + (PTL_WRITABLE \| PTL_PRESENT)
[a1f60f3]	643	.fill 255, 8, 0
[6f878b7]	644
[19077a5]	645	.section K_DATA_START, "aw", @progbits
	646
[1f5c9c96]	647	.global bootstrap_gdtr
[46d26ee]	648	bootstrap_gdtr:
[1d3d2cf]	649	.word GDT_SELECTOR(GDT_ITEMS)
[1a67595]	650	.long KA2PA(gdt)
[46d26ee]	651
[1f5c9c96]	652	.global multiboot_eax
	653	multiboot_eax:
[46d26ee]	654	.long 0
	655
[1f5c9c96]	656	.global multiboot_ebx
	657	multiboot_ebx:
[46d26ee]	658	.long 0
[ac88c93]	659
[873c681]	660	err_extended_cpuid:
[fccc236]	661	.asciz "Error: Extended CPUID not supported -- CPU is not 64-bit. System halted."
[873c681]	662	err_long_mode:
[fccc236]	663	.asciz "Error: 64-bit long mode not supported. System halted."
[873c681]	664	err_noexecute:
[fccc236]	665	.asciz "Error: No-execute pages not supported. System halted."
[873c681]	666	err_fx:
[fccc236]	667	.asciz "Error: FXSAVE/FXRESTORE instructions not supported. System halted."
[873c681]	668	err_sse2:
[fccc236]	669	.asciz "Error: SSE2 instructions not supported. System halted."
[873c681]	670
	671	status_prot:
	672	.asciz "[prot] "
	673	status_vesa_copy:
	674	.asciz "[vesa_copy] "
[1f5c9c96]	675	status_multiboot_cmdline:
	676	.asciz "[multiboot_cmdline] "
[873c681]	677	status_vesa_real:
	678	.asciz "[vesa_real] "
	679	status_prot2:
	680	.asciz "[prot2] "
	681	status_long:
	682	.asciz "[long] "
	683	status_main:
	684	.asciz "[main] "

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format