Context Navigation

boot.S@ cb4afd8b

Visit:

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export

Last change on this file since cb4afd8b was 4f42d52, checked in by Martin Decky <martin@…>, 19 years ago
force VGA palette to 3:2:3 palette on 8 bpp modes (this fixes ticket #33)
Property mode set to `100644`
File size: 14.1 KB

Line
1	#
2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky
4	# All rights reserved.
5	#
6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions
8	# are met:
9	#
10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.
17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#
29
30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>
33	#include <arch/mm/ptl.h>
34	#include <arch/pm.h>
35	#include <arch/cpu.h>
36	#include <arch/cpuid.h>
37
38	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
39
40	.section K_TEXT_START, "ax"
41
42	.code32
43	.align 4
44	.global multiboot_image_start
45	multiboot_header:
46	.long MULTIBOOT_HEADER_MAGIC
47	.long MULTIBOOT_HEADER_FLAGS
48	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
49	.long multiboot_header
50	.long unmapped_ktext_start
51	.long 0
52	.long 0
53	.long multiboot_image_start
54
55	multiboot_image_start:
56	movl $START_STACK, %esp # initialize stack pointer
57	lgdt bootstrap_gdtr # initialize Global Descriptor Table register
58
59	movw $gdtselector(KDATA_DES), %cx
60	movw %cx, %es
61	movw %cx, %ds # kernel data + stack
62	movw %cx, %ss
63	# Simics seems to remove hidden part of GS on entering user mode
64	# when _visible_ part of GS does not point to user-mode segment
65	movw $gdtselector(UDATA_DES), %cx
66	movw %cx, %fs
67	movw %cx, %gs
68
69	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
70	multiboot_meeting_point:
71
72	movl %eax, grub_eax # save parameters from GRUB
73	movl %ebx, grub_ebx
74
75	# Protected 32-bit. We want to reuse the code-seg descriptor,
76	# the Default operand size must not be 1 when entering long mode
77
78	movl $0x80000000, %eax
79	cpuid
80	cmp $0x80000000, %eax # any function > 80000000h?
81	jbe long_mode_unsupported
82	movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001
83	cpuid
84	bt $29, %edx # Test if long mode is supported.
85	jc long_mode_supported
86
87	long_mode_unsupported:
88	movl $long_mode_msg, %esi
89	jmp error_halt
90
91	long_mode_supported:
92
93	#ifdef CONFIG_FB
94	mov $vesa_init, %esi
95	mov $VESA_INIT_SEGMENT << 4, %edi
96	mov $e_vesa_init - vesa_init, %ecx
97	cld
98	rep movsb
99
100	mov $VESA_INIT_SEGMENT << 4, %edi
101	jmpl *%edi
102
103	vesa_meeting_point:
104
105	mov %esi, KA2PA(vesa_ph_addr)
106	mov %di, KA2PA(vesa_height)
107	shr $16, %edi
108	mov %di, KA2PA(vesa_width)
109	mov %bx, KA2PA(vesa_scanline)
110	shr $16, %ebx
111	mov %bx, KA2PA(vesa_bpp)
112	#endif
113
114	# Enable 64-bit page transaltion entries - CR4.PAE = 1.
115	# Paging is not enabled until after long mode is enabled
116
117	movl %cr4, %eax
118	btsl $5, %eax
119	movl %eax, %cr4
120
121	# Set up paging tables
122
123	leal ptl_0, %eax
124	movl %eax, %cr3
125
126	# Enable long mode
127
128	movl $EFER_MSR_NUM, %ecx # EFER MSR number
129	rdmsr # Read EFER
130	btsl $AMD_LME_FLAG, %eax # Set LME=1
131	wrmsr # Write EFER
132
133	# Enable paging to activate long mode (set CR0.PG=1)
134
135	movl %cr0, %eax
136	btsl $31, %eax
137	movl %eax, %cr0
138
139	# At this point we are in compatibility mode
140
141	jmpl $gdtselector(KTEXT_DES), $start64
142
143	.code64
144	start64:
145	movq $(PA2KA(START_STACK)), %rsp
146	movl grub_eax, %eax
147	movl grub_ebx, %ebx
148
149	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
150	je valid_boot
151
152	xorl %ecx, %ecx # no memory size or map available
153	movl %ecx, e801memorysize
154	movl %ecx, e820counter
155
156	jmp invalid_boot
157
158	valid_boot:
159
160	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
161
162	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
163	jc mem_valid
164
165	xorl %ecx, %ecx
166	jmp mem_invalid
167
168	mem_valid:
169	movl 4(%ebx), %ecx # mbi->mem_lower
170	addl 8(%ebx), %ecx # mbi->mem_upper
171
172	mem_invalid:
173	movl %ecx, e801memorysize
174
175	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
176	jc mods_valid
177
178	xorq %rcx, %rcx
179	movq %rcx, init
180	jmp mods_end
181
182	mods_valid:
183
184	xorq %rcx, %rcx
185	movl 20(%ebx), %ecx # mbi->mods_count
186	movq %rcx, init
187
188	cmpl $0, %ecx
189	je mods_end
190
191	movl 24(%ebx), %esi # mbi->mods_addr
192	movq $init, %rdi
193
194	mods_loop:
195
196	xorq %rdx, %rdx
197	movl 0(%esi), %edx # mods->mod_start
198	movq $0xffff800000000000, %r10
199	addq %r10, %rdx
200	movq %rdx, 8(%rdi)
201
202	xorq %rdx, %rdx
203	movl 4(%esi), %edx
204	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
205	movq %rdx, 16(%rdi)
206
207	addl $16, %esi
208	addq $16, %rdi
209
210	loop mods_loop
211
212	mods_end:
213
214	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
215	jc mmap_valid
216
217	xorl %edx, %edx
218	jmp mmap_invalid
219
220	mmap_valid:
221	movl 44(%ebx), %ecx # mbi->mmap_length
222	movl 48(%ebx), %esi # mbi->mmap_addr
223	movq $e820table, %rdi
224	xorl %edx, %edx
225
226	mmap_loop:
227	cmpl $0, %ecx
228	jle mmap_end
229
230	movl 4(%esi), %eax # mmap->base_addr_low
231	movl %eax, (%rdi)
232
233	movl 8(%esi), %eax # mmap->base_addr_high
234	movl %eax, 4(%rdi)
235
236	movl 12(%esi), %eax # mmap->length_low
237	movl %eax, 8(%rdi)
238
239	movl 16(%esi), %eax # mmap->length_high
240	movl %eax, 12(%rdi)
241
242	movl 20(%esi), %eax # mmap->type
243	movl %eax, 16(%rdi)
244
245	movl (%esi), %eax # mmap->size
246	addl $0x4, %eax
247	addl %eax, %esi
248	subl %eax, %ecx
249	addq $MEMMAP_E820_RECORD_SIZE, %rdi
250	incl %edx
251	jmp mmap_loop
252
253	mmap_end:
254
255	mmap_invalid:
256	movl %edx, e820counter
257
258	invalid_boot:
259
260	#ifdef CONFIG_SMP
261
262	# copy AP bootstrap routines below 1 MB
263
264	movq $BOOT_OFFSET, %rsi
265	movq $AP_BOOT_OFFSET, %rdi
266	movq $_hardcoded_unmapped_size, %rcx
267	cld
268	rep movsb
269
270	#endif
271
272	call main_bsp # never returns
273
274	cli
275	hlt
276
277	#ifdef CONFIG_FB
278	.code32
279	vesa_init:
280	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
281
282	.code16
283	vesa_init_real:
284
285	mov %cr0, %eax
286	and $~1, %eax
287	mov %eax, %cr0
288
289	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
290
291	vesa_init_real2:
292
293	mov $VESA_INIT_SEGMENT, %bx
294
295	mov %bx, %es
296	mov %bx, %fs
297	mov %bx, %gs
298	mov %bx, %ds
299	mov %bx, %ss
300
301	movl $0x0000fffc, %esp
302	movl $0x0000fffc, %ebp
303
304	#define VESA_INFO_SIZE 1024
305
306	#define VESA_MODE_ATTRIBUTES_OFFSET 0
307	#define VESA_MODE_LIST_PTR_OFFSET 14
308	#define VESA_MODE_SCANLINE_OFFSET 16
309	#define VESA_MODE_WIDTH_OFFSET 18
310	#define VESA_MODE_HEIGHT_OFFSET 20
311	#define VESA_MODE_BPP_OFFSET 25
312	#define VESA_MODE_PHADDR_OFFSET 40
313
314	#define VESA_END_OF_MODES 0xffff
315
316	#define VESA_OK 0x4f
317
318	#define VESA_GET_INFO 0x4f00
319	#define VESA_GET_MODE_INFO 0x4f01
320	#define VESA_SET_MODE 0x4f02
321	#define VESA_SET_PALETTE 0x4f09
322
323	#define CONFIG_VESA_BPP_a 255
324
325	#if CONFIG_VESA_BPP == 24
326	#define CONFIG_VESA_BPP_VARIANT 32
327	#endif
328
329	mov $VESA_GET_INFO, %ax
330	mov $e_vesa_init - vesa_init, %di
331	push %di
332	int $0x10
333
334	pop %di
335	cmp $VESA_OK, %al
336	jnz 0f
337
338	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
339	mov %si, %gs
340	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
341
342	add $VESA_INFO_SIZE, %di
343
344	1:# Try next mode
345	mov %gs:(%si), %cx
346	cmp $VESA_END_OF_MODES, %cx
347	jz 0f
348
349	inc %si
350	inc %si
351	push %cx
352	push %di
353	push %si
354	mov $VESA_GET_MODE_INFO, %ax
355	int $0x10
356
357	pop %si
358	pop %di
359	pop %cx
360	cmp $VESA_OK, %al
361	jnz 0f
362
363	mov $CONFIG_VESA_WIDTH, %ax
364	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
365	jnz 1b
366
367	mov $CONFIG_VESA_HEIGHT, %ax
368	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
369	jnz 1b
370
371	mov $CONFIG_VESA_BPP, %al
372	cmp VESA_MODE_BPP_OFFSET(%di), %al
373
374	#ifdef CONFIG_VESA_BPP_VARIANT
375	jz 2f
376
377	mov $CONFIG_VESA_BPP_VARIANT, %al
378	cmp VESA_MODE_BPP_OFFSET(%di), %al
379	#endif
380	jnz 1b
381
382	2:
383
384	mov %cx, %bx
385	or $0xc000, %bx
386	push %di
387	mov $VESA_SET_MODE, %ax
388	int $0x10
389
390	pop %di
391	cmp $VESA_OK, %al
392	jnz 0f
393
394	#if CONFIG_VESA_BPP == 8
395
396	# Set 3:2:3 VGA palette
397
398	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
399	push %di
400	mov $vga323 - vesa_init, %di
401	mov $0x100, %ecx
402
403	bt $5, %ax # Test if VGA compatible registers are present
404	jnc vga_compat
405
406	# Try VESA routine to set palette
407
408	mov $VESA_SET_PALETTE, %ax
409	xor %bl, %bl
410	xor %dx, %dx
411	int $0x10
412
413	jmp vga_not_compat
414
415	vga_compat:
416
417	# Try VGA registers to set palette
418
419	movw $0x3c6, %dx # Set palette mask
420	movb $0xff, %al
421	outb %al, %dx
422
423	movw $0x3c8, %dx # First index to set
424	xor %al, %al
425	outb %al, %dx
426
427	movw $0x3c9, %dx # Data port
428	vga_loop:
429	movb %es:2(%di), %al
430	outb %al, %dx
431
432	movb %es:1(%di), %al
433	outb %al, %dx
434
435	movb %es:(%di), %al
436	outb %al, %dx
437
438	addw $4, %di
439	loop vga_loop
440
441	vga_not_compat:
442
443	pop %di
444
445	#endif
446
447	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
448	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
449	shl $16, %eax
450	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
451	mov VESA_MODE_BPP_OFFSET(%di), %bl
452	xor %bh, %bh
453	shl $16, %ebx
454	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
455	mov %eax, %edi
456
457	8:
458
459	mov %cr0, %eax
460	or $1, %eax
461	mov %eax, %cr0
462
463	jmp 9f
464	9:
465
466	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
467
468	0:# No prefered mode found
469	mov $0x111, %cx
470	push %di
471	push %cx
472	mov $VESA_GET_MODE_INFO, %ax
473	int $0x10
474
475	pop %cx
476	pop %di
477	cmp $VESA_OK, %al
478	jnz 1f
479	jz 2b # Force relative jump
480
481	1:
482	mov $0x0003, %ax
483	int $0x10
484	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
485	xor %ax, %ax
486	jz 8b # Force relative jump
487
488	vga323:
489	#include "vga323.pal"
490
491	.code32
492	vesa_init_protect:
493	movw $gdtselector(KDATA_DES), %cx
494	movw %cx, %es
495	movw %cx, %ds # kernel data + stack
496	movw %cx, %ss
497	# Simics seems to remove hidden part of GS on entering user mode
498	# when _visible_ part of GS does not point to user-mode segment
499	movw $gdtselector(UDATA_DES), %cx
500	movw %cx, %fs
501	movw %cx, %gs
502
503	movl $START_STACK, %esp # initialize stack pointer
504
505	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
506
507	.align 4
508	e_vesa_init:
509	#endif
510
511	# Print string from %esi to EGA display (in red) and halt
512	error_halt:
513	movl $0xb8000, %edi # base of EGA text mode memory
514	xorl %eax, %eax
515
516	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
517	movb $0xe, %al
518	outb %al, %dx
519
520	movw $0x3d5, %dx
521	inb %dx, %al
522	shl $8, %ax
523
524	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
525	movb $0xf, %al
526	outb %al, %dx
527
528	movw $0x3d5, %dx
529	inb %dx, %al
530
531	cmp $1920, %ax
532	jbe cursor_ok
533	movw $1920, %ax # sanity check for the cursor on the last line
534	cursor_ok:
535
536	movw %ax, %bx
537	shl $1, %eax
538	addl %eax, %edi
539
540	movw $0x0c00, %ax # black background, light red foreground
541	cld
542
543	ploop:
544	lodsb
545	cmp $0, %al
546	je ploop_end
547	stosw
548	inc %bx
549	jmp ploop
550	ploop_end:
551
552	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
553	movb $0xe, %al
554	outb %al, %dx
555
556	movw $0x3d5, %dx
557	movb %bh, %al
558	outb %al, %dx
559
560	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
561	movb $0xf, %al
562	outb %al, %dx
563
564	movw $0x3d5, %dx
565	movb %bl, %al
566	outb %al, %dx
567
568	cli
569	hlt
570
571	.section K_DATA_START, "aw", @progbits
572	.align 4096
573
574	# Identical mapping of first 64MB and the same of -2GB -> 0
575	.global ptl_2
576	ptl_2:
577	.quad 0x0 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
578	.quad 0x200000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
579	.quad 0x400000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
580	.quad 0x600000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
581	.quad 0x800000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
582	.quad 0xa00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
583	.quad 0xc00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
584	.quad 0xe00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
585	.quad 0x1000000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
586	.quad 0x1200000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
587	.quad 0x1400000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
588	.quad 0x1600000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
589	.quad 0x1800000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
590	.quad 0x1a00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
591	.quad 0x1c00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
592	.quad 0x1e00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
593	.quad 0x2000000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
594	.quad 0x2200000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
595	.quad 0x2400000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
596	.quad 0x2600000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
597	.quad 0x2800000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
598	.quad 0x2a00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
599	.quad 0x2c00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
600	.quad 0x2e00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
601	.quad 0x3000000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
602	.quad 0x3200000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
603	.quad 0x3400000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
604	.quad 0x3600000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
605	.quad 0x3800000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
606	.quad 0x3a00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
607	.quad 0x3c00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
608	.quad 0x3e00000 \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
609
610	.align 4096
611	.global ptl_1
612	ptl_1:
613	.quad ptl_2 + (PTL_WRITABLE \| PTL_PRESENT)
614	.fill 509,8,0
615	.quad ptl_2 + (PTL_WRITABLE \| PTL_PRESENT)
616	.fill 1,8,0
617
618	.align 4096
619	.global ptl_0
620	ptl_0:
621	.quad ptl_1 + (PTL_WRITABLE \| PTL_PRESENT)
622	.fill 255,8,0
623	.quad ptl_1 + (PTL_WRITABLE \| PTL_PRESENT)
624	.fill 254,8,0
625	.quad ptl_1 + (PTL_WRITABLE \| PTL_PRESENT)
626
627	.global bootstrap_gdtr
628	bootstrap_gdtr:
629	.word gdtselector(GDT_ITEMS)
630	.long KA2PA(gdt)
631
632	grub_eax:
633	.long 0
634
635	grub_ebx:
636	.long 0
637
638	long_mode_msg:
639	.asciz "64 bit long mode not supported. System halted."

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format