source: mainline/kernel/arch/amd64/src/boot/boot.S@ ac88c93

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since ac88c93 was ac88c93, checked in by Martin Decky <martin@…>, 18 years ago

add error message on no long mode support
  • Property mode set to 100644
File size: 13.1 KB
Line 
1#
2# Copyright (c) 2005 Ondrej Palkovsky
3# Copyright (c) 2006 Martin Decky
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions
8# are met:
9#
10# - Redistributions of source code must retain the above copyright
11# notice, this list of conditions and the following disclaimer.
12# - Redistributions in binary form must reproduce the above copyright
13# notice, this list of conditions and the following disclaimer in the
14# documentation and/or other materials provided with the distribution.
15# - The name of the author may not be used to endorse or promote products
16# derived from this software without specific prior written permission.
17#
18# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29
30#include <arch/boot/boot.h>
31#include <arch/boot/memmap.h>
32#include <arch/mm/page.h>
33#include <arch/mm/ptl.h>
34#include <arch/pm.h>
35#include <arch/cpu.h>
36#include <arch/cpuid.h>
37
38#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
39
40.section K_TEXT_START, "ax"
41
42.code32
43.align 4
44.global multiboot_image_start
45multiboot_header:
46 .long MULTIBOOT_HEADER_MAGIC
47 .long MULTIBOOT_HEADER_FLAGS
48 .long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
49 .long multiboot_header
50 .long unmapped_ktext_start
51 .long 0
52 .long 0
53 .long multiboot_image_start
54
55multiboot_image_start:
56 movl $START_STACK, %esp # initialize stack pointer
57 lgdt bootstrap_gdtr # initialize Global Descriptor Table register
58
59 movw $gdtselector(KDATA_DES), %cx
60 movw %cx, %es
61 movw %cx, %ds # kernel data + stack
62 movw %cx, %ss
63 # Simics seems to remove hidden part of GS on entering user mode
64 # when _visible_ part of GS does not point to user-mode segment
65 movw $gdtselector(UDATA_DES), %cx
66 movw %cx, %fs
67 movw %cx, %gs
68
69 jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
70 multiboot_meeting_point:
71
72 movl %eax, grub_eax # save parameters from GRUB
73 movl %ebx, grub_ebx
74
75 # Protected 32-bit. We want to reuse the code-seg descriptor,
76 # the Default operand size must not be 1 when entering long mode
77
78 movl $0x80000000, %eax
79 cpuid
80 cmp $0x80000000, %eax # any function > 80000000h?
81 jbe long_mode_unsupported
82 movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001
83 cpuid
84 bt $29, %edx # Test if long mode is supported.
85 jc long_mode_supported
86
87 long_mode_unsupported:
88 movl $long_mode_msg, %esi
89 jmp error_halt
90
91 long_mode_supported:
92
93#ifdef CONFIG_FB
94 mov $vesa_init, %esi
95 mov $VESA_INIT_SEGMENT << 4, %edi
96 mov $e_vesa_init - vesa_init, %ecx
97 cld
98 rep movsb
99
100 mov $VESA_INIT_SEGMENT << 4, %edi
101 jmpl *%edi
102
103 vesa_meeting_point:
104
105 mov %esi, KA2PA(vesa_ph_addr)
106 mov %di, KA2PA(vesa_height)
107 shr $16, %edi
108 mov %di, KA2PA(vesa_width)
109 mov %bx, KA2PA(vesa_scanline)
110 shr $16, %ebx
111 mov %bx, KA2PA(vesa_bpp)
112#endif
113
114 # Enable 64-bit page transaltion entries - CR4.PAE = 1.
115 # Paging is not enabled until after long mode is enabled
116
117 movl %cr4, %eax
118 btsl $5, %eax
119 movl %eax, %cr4
120
121 # Set up paging tables
122
123 leal ptl_0, %eax
124 movl %eax, %cr3
125
126 # Enable long mode
127
128 movl $EFER_MSR_NUM, %ecx # EFER MSR number
129 rdmsr # Read EFER
130 btsl $AMD_LME_FLAG, %eax # Set LME=1
131 wrmsr # Write EFER
132
133 # Enable paging to activate long mode (set CR0.PG=1)
134
135 movl %cr0, %eax
136 btsl $31, %eax
137 movl %eax, %cr0
138
139 # At this point we are in compatibility mode
140
141 jmpl $gdtselector(KTEXT_DES), $start64
142
143.code64
144start64:
145 movq $(PA2KA(START_STACK)), %rsp
146 movl grub_eax, %eax
147 movl grub_ebx, %ebx
148
149 cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
150 je valid_boot
151
152 xorl %ecx, %ecx # no memory size or map available
153 movl %ecx, e801memorysize
154 movl %ecx, e820counter
155
156 jmp invalid_boot
157
158 valid_boot:
159
160 movl (%ebx), %eax # ebx = physical address of struct multiboot_info
161
162 bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
163 jc mem_valid
164
165 xorl %ecx, %ecx
166 jmp mem_invalid
167
168 mem_valid:
169 movl 4(%ebx), %ecx # mbi->mem_lower
170 addl 8(%ebx), %ecx # mbi->mem_upper
171
172 mem_invalid:
173 movl %ecx, e801memorysize
174
175 bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
176 jc mods_valid
177
178 xorq %rcx, %rcx
179 movq %rcx, init
180 jmp mods_end
181
182 mods_valid:
183
184 xorq %rcx, %rcx
185 movl 20(%ebx), %ecx # mbi->mods_count
186 movq %rcx, init
187
188 cmpl $0, %ecx
189 je mods_end
190
191 movl 24(%ebx), %esi # mbi->mods_addr
192 movq $init, %rdi
193
194 mods_loop:
195
196 xorq %rdx, %rdx
197 movl 0(%esi), %edx # mods->mod_start
198 movq $0xffff800000000000, %r10
199 addq %r10, %rdx
200 movq %rdx, 8(%rdi)
201
202 xorq %rdx, %rdx
203 movl 4(%esi), %edx
204 subl 0(%esi), %edx # mods->mod_end - mods->mod_start
205 movq %rdx, 16(%rdi)
206
207 addl $16, %esi
208 addq $16, %rdi
209
210 loop mods_loop
211
212 mods_end:
213
214 bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
215 jc mmap_valid
216
217 xorl %edx, %edx
218 jmp mmap_invalid
219
220 mmap_valid:
221 movl 44(%ebx), %ecx # mbi->mmap_length
222 movl 48(%ebx), %esi # mbi->mmap_addr
223 movq $e820table, %rdi
224 xorl %edx, %edx
225
226 mmap_loop:
227 cmpl $0, %ecx
228 jle mmap_end
229
230 movl 4(%esi), %eax # mmap->base_addr_low
231 movl %eax, (%rdi)
232
233 movl 8(%esi), %eax # mmap->base_addr_high
234 movl %eax, 4(%rdi)
235
236 movl 12(%esi), %eax # mmap->length_low
237 movl %eax, 8(%rdi)
238
239 movl 16(%esi), %eax # mmap->length_high
240 movl %eax, 12(%rdi)
241
242 movl 20(%esi), %eax # mmap->type
243 movl %eax, 16(%rdi)
244
245 movl (%esi), %eax # mmap->size
246 addl $0x4, %eax
247 addl %eax, %esi
248 subl %eax, %ecx
249 addq $MEMMAP_E820_RECORD_SIZE, %rdi
250 incl %edx
251 jmp mmap_loop
252
253 mmap_end:
254
255 mmap_invalid:
256 movl %edx, e820counter
257
258 invalid_boot:
259
260#ifdef CONFIG_SMP
261
262 # copy AP bootstrap routines below 1 MB
263
264 movq $BOOT_OFFSET, %rsi
265 movq $AP_BOOT_OFFSET, %rdi
266 movq $_hardcoded_unmapped_size, %rcx
267 cld
268 rep movsb
269
270#endif
271
272 call main_bsp # never returns
273
274 cli
275 hlt
276
277#ifdef CONFIG_FB
278.code32
279vesa_init:
280 jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
281
282.code16
283vesa_init_real:
284
285 mov %cr0, %eax
286 and $~1, %eax
287 mov %eax, %cr0
288
289 jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
290
291vesa_init_real2:
292
293 mov $VESA_INIT_SEGMENT, %bx
294
295 mov %bx, %es
296 mov %bx, %fs
297 mov %bx, %gs
298 mov %bx, %ds
299 mov %bx, %ss
300
301 movl $0x0000fffc, %esp
302 movl $0x0000fffc, %ebp
303
304#define VESA_INFO_SIZE 1024
305
306#define VESA_MODE_LIST_PTR_OFFSET 14
307#define VESA_MODE_WIDTH_OFFSET 18
308#define VESA_MODE_HEIGHT_OFFSET 20
309#define VESA_MODE_BPP_OFFSET 25
310#define VESA_MODE_SCANLINE_OFFSET 16
311#define VESA_MODE_PHADDR_OFFSET 40
312
313#define VESA_END_OF_MODES 0xffff
314
315#define VESA_OK 0x4f
316
317#define VESA_GET_INFO 0x4f00
318#define VESA_GET_MODE_INFO 0x4f01
319#define VESA_SET_MODE 0x4f02
320
321#define CONFIG_VESA_BPP_a 255
322
323#if CONFIG_VESA_BPP == 24
324#undef CONFIG_VESA_BPP_a
325#define CONFIG_VESA_BPP_a 32
326#endif
327
328 mov $VESA_GET_INFO, %ax
329 mov $e_vesa_init - vesa_init, %di
330 push %di
331 int $0x10
332
333 pop %di
334 cmp $VESA_OK, %al
335 jnz 0f
336
337 mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
338 mov %si, %gs
339 mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
340
341 add $VESA_INFO_SIZE, %di
342
3431:# Try next mode
344 mov %gs:(%si), %cx
345 cmp $VESA_END_OF_MODES, %cx
346 jz 0f
347
348 inc %si
349 inc %si
350 push %cx
351 push %di
352 push %si
353 mov $VESA_GET_MODE_INFO, %ax
354 int $0x10
355
356 pop %si
357 pop %di
358 pop %cx
359 cmp $VESA_OK, %al
360 jnz 0f
361
362 mov $CONFIG_VESA_WIDTH, %ax
363 cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
364 jnz 1b
365
366 mov $CONFIG_VESA_HEIGHT, %ax
367 cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
368 jnz 1b
369
370 mov $CONFIG_VESA_BPP, %al
371 cmp VESA_MODE_BPP_OFFSET(%di), %al
372 jz 2f
373
374 mov $CONFIG_VESA_BPP_a, %al
375 cmp VESA_MODE_BPP_OFFSET(%di), %al
376 jnz 1b
377
3782:
379
380 mov %cx, %bx
381 or $0xc000, %bx
382 push %di
383 mov $VESA_SET_MODE, %ax
384 int $0x10
385
386 pop %di
387 cmp $VESA_OK, %al
388 jnz 0f
389
390 mov VESA_MODE_PHADDR_OFFSET(%di), %esi
391 mov VESA_MODE_WIDTH_OFFSET(%di), %ax
392 shl $16, %eax
393 mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
394 mov VESA_MODE_BPP_OFFSET(%di), %bl
395 xor %bh, %bh
396 shl $16, %ebx
397 mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
398 mov %eax, %edi
399
4008:
401
402 mov %cr0, %eax
403 or $1, %eax
404 mov %eax, %cr0
405
406 jmp 9f
4079:
408
409 ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
410
4110:# No prefered mode found
412 mov $0x111, %cx
413 push %di
414 push %cx
415 mov $VESA_GET_MODE_INFO, %ax
416 int $0x10
417
418 pop %cx
419 pop %di
420 cmp $VESA_OK, %al
421 jnz 1f
422 jz 2b # Force relative jump
423
4241:
425 mov $0x0003, %ax
426 int $0x10
427 mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
428 xor %ax, %ax
429 jz 8b # Force relative jump
430
431
432.code32
433vesa_init_protect:
434 movw $gdtselector(KDATA_DES), %cx
435 movw %cx, %es
436 movw %cx, %ds # kernel data + stack
437 movw %cx, %ss
438 # Simics seems to remove hidden part of GS on entering user mode
439 # when _visible_ part of GS does not point to user-mode segment
440 movw $gdtselector(UDATA_DES), %cx
441 movw %cx, %fs
442 movw %cx, %gs
443
444 jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
445
446.align 4
447e_vesa_init:
448#endif
449
450# Print string from %esi to EGA display (in red) and halt
451error_halt:
452 movl $0xb8000, %edi # base of EGA text mode memory
453 xorl %eax, %eax
454
455 movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
456 movb $0xe, %al
457 outb %al, %dx
458
459 movw $0x3d5, %dx
460 inb %dx, %al
461 shl $8, %ax
462
463 movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
464 movb $0xf, %al
465 outb %al, %dx
466
467 movw $0x3d5, %dx
468 inb %dx, %al
469
470 cmp $1920, %ax
471 jbe cursor_ok
472 movw $1920, %ax # sanity check for the cursor on the last line
473 cursor_ok:
474
475 movw %ax, %bx
476 shl $1, %eax
477 addl %eax, %edi
478
479 movw $0x0c00, %ax # black background, light red foreground
480 cld
481
482 ploop:
483 lodsb
484 cmp $0, %al
485 je ploop_end
486 stosw
487 inc %bx
488 jmp ploop
489 ploop_end:
490
491 movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
492 movb $0xe, %al
493 outb %al, %dx
494
495 movw $0x3d5, %dx
496 movb %bh, %al
497 outb %al, %dx
498
499 movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
500 movb $0xf, %al
501 outb %al, %dx
502
503 movw $0x3d5, %dx
504 movb %bl, %al
505 outb %al, %dx
506
507 cli
508 hlt
509
510.section K_DATA_START, "aw", @progbits
511.align 4096
512
513# Identical mapping of first 64MB and the same of -2GB -> 0
514.global ptl_2
515ptl_2:
516 .quad 0x0 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
517 .quad 0x200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
518 .quad 0x400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
519 .quad 0x600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
520 .quad 0x800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
521 .quad 0xa00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
522 .quad 0xc00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
523 .quad 0xe00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
524 .quad 0x1000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
525 .quad 0x1200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
526 .quad 0x1400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
527 .quad 0x1600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
528 .quad 0x1800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
529 .quad 0x1a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
530 .quad 0x1c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
531 .quad 0x1e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
532 .quad 0x2000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
533 .quad 0x2200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
534 .quad 0x2400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
535 .quad 0x2600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
536 .quad 0x2800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
537 .quad 0x2a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
538 .quad 0x2c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
539 .quad 0x2e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
540 .quad 0x3000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
541 .quad 0x3200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
542 .quad 0x3400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
543 .quad 0x3600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
544 .quad 0x3800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
545 .quad 0x3a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
546 .quad 0x3c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
547 .quad 0x3e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
548
549.align 4096
550.global ptl_1
551ptl_1:
552 .quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
553 .fill 509,8,0
554 .quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
555 .fill 1,8,0
556
557.align 4096
558.global ptl_0
559ptl_0:
560 .quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
561 .fill 255,8,0
562 .quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
563 .fill 254,8,0
564 .quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
565
566.global bootstrap_gdtr
567bootstrap_gdtr:
568 .word gdtselector(GDT_ITEMS)
569 .long KA2PA(gdt)
570
571grub_eax:
572 .long 0
573
574grub_ebx:
575 .long 0
576
577long_mode_msg:
578 .ascii "64 bit long mode not supported. System halted.\0"
Note: See TracBrowser for help on using the repository browser.