source: mainline/kernel/arch/amd64/src/asm.S@ a759467

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since a759467 was a7220de, checked in by Jakub Jermar <jakub@…>, 15 years ago

Rewrite syscall_entry() to use the istate structure and save all GPRs in it.
  • Property mode set to 100644
File size: 13.0 KB
Line 
1/*
2 * Copyright (c) 2005 Ondrej Palkovsky
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *
9 * - Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * - Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 * - The name of the author may not be used to endorse or promote products
15 * derived from this software without specific prior written permission.
16 *
17 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27 */
28
29#include <arch/pm.h>
30#include <arch/mm/page.h>
31
32.text
33.global interrupt_handlers
34.global syscall_entry
35.global cpuid
36.global has_cpuid
37.global read_efer_flag
38.global set_efer_flag
39.global memsetb
40.global memsetw
41.global memcpy
42.global memcpy_from_uspace
43.global memcpy_to_uspace
44.global memcpy_from_uspace_failover_address
45.global memcpy_to_uspace_failover_address
46.global early_putchar
47
48/* Wrapper for generic memsetb */
49memsetb:
50 jmp _memsetb
51
52/* Wrapper for generic memsetw */
53memsetw:
54 jmp _memsetw
55
56#define MEMCPY_DST %rdi
57#define MEMCPY_SRC %rsi
58#define MEMCPY_SIZE %rdx
59
60/**
61 * Copy memory from/to userspace.
62 *
63 * This is almost conventional memcpy().
64 * The difference is that there is a failover part
65 * to where control is returned from a page fault if
66 * the page fault occurs during copy_from_uspace()
67 * or copy_to_uspace().
68 *
69 * @param MEMCPY_DST Destination address.
70 * @param MEMCPY_SRC Source address.
71 * @param MEMCPY_SIZE Number of bytes to copy.
72 *
73 * @retrun MEMCPY_DST on success, 0 on failure.
74 *
75 */
76memcpy:
77memcpy_from_uspace:
78memcpy_to_uspace:
79 movq MEMCPY_DST, %rax
80
81 movq MEMCPY_SIZE, %rcx
82 shrq $3, %rcx /* size / 8 */
83
84 rep movsq /* copy as much as possible word by word */
85
86 movq MEMCPY_SIZE, %rcx
87 andq $7, %rcx /* size % 8 */
88 jz 0f
89
90 rep movsb /* copy the rest byte by byte */
91
92 0:
93 ret /* return MEMCPY_SRC, success */
94
95memcpy_from_uspace_failover_address:
96memcpy_to_uspace_failover_address:
97 xorq %rax, %rax /* return 0, failure */
98 ret
99
100/** Determine CPUID support
101*
102* @return 0 in EAX if CPUID is not support, 1 if supported.
103*
104*/
105has_cpuid:
106 /* Load RFLAGS */
107 pushfq
108 popq %rax
109 movq %rax, %rdx
110
111 /* Flip the ID bit */
112 btcl $21, %edx
113
114 /* Store RFLAGS */
115 pushq %rdx
116 popfq
117 pushfq
118
119 /* Get the ID bit again */
120 popq %rdx
121 andl $(1 << 21), %eax
122 andl $(1 << 21), %edx
123
124 /* 0 if not supported, 1 if supported */
125 xorl %edx, %eax
126 ret
127
128cpuid:
129 /* Preserve %rbx across function calls */
130 movq %rbx, %r10
131
132 /* Load the command into %eax */
133 movl %edi, %eax
134
135 cpuid
136 movl %eax, 0(%rsi)
137 movl %ebx, 4(%rsi)
138 movl %ecx, 8(%rsi)
139 movl %edx, 12(%rsi)
140
141 movq %r10, %rbx
142 ret
143
144set_efer_flag:
145 movq $0xc0000080, %rcx
146 rdmsr
147 btsl %edi, %eax
148 wrmsr
149 ret
150
151read_efer_flag:
152 movq $0xc0000080, %rcx
153 rdmsr
154 ret
155
156#define ISTATE_OFFSET_RAX 0
157#define ISTATE_OFFSET_RBX 8
158#define ISTATE_OFFSET_RCX 16
159#define ISTATE_OFFSET_RDX 24
160#define ISTATE_OFFSET_RSI 32
161#define ISTATE_OFFSET_RDI 40
162#define ISTATE_OFFSET_RBP 48
163#define ISTATE_OFFSET_R8 56
164#define ISTATE_OFFSET_R9 64
165#define ISTATE_OFFSET_R10 72
166#define ISTATE_OFFSET_R11 80
167#define ISTATE_OFFSET_R12 88
168#define ISTATE_OFFSET_R13 96
169#define ISTATE_OFFSET_R14 104
170#define ISTATE_OFFSET_R15 112
171#define ISTATE_OFFSET_ALIGNMENT 120
172#define ISTATE_OFFSET_RBP_FRAME 128
173#define ISTATE_OFFSET_RIP_FRAME 136
174#define ISTATE_OFFSET_ERROR_WORD 144
175#define ISTATE_OFFSET_RIP 152
176#define ISTATE_OFFSET_CS 160
177#define ISTATE_OFFSET_RFLAGS 168
178#define ISTATE_OFFSET_RSP 176
179#define ISTATE_OFFSET_SS 184
180
181/*
182 * Size of the istate structure without the hardware-saved part and without the
183 * error word.
184 */
185#define ISTATE_SOFT_SIZE 144
186
187/**
188 * Mask for interrupts 0 - 31 (bits 0 - 31) where 0 means that int
189 * has no error word and 1 means interrupt with error word
190 *
191 */
192#define ERROR_WORD_INTERRUPT_LIST 0x00027D00
193
194#define INTERRUPT_ALIGN 256
195
196/** Declare interrupt handlers
197 *
198 * Declare interrupt handlers for n interrupt
199 * vectors starting at vector i.
200 *
201 * The handlers call exc_dispatch().
202 *
203 */
204.macro handler i n
205
206 /*
207 * Choose between version with error code and version without error
208 * code. Both versions have to be of the same size. amd64 assembly is,
209 * however, a little bit tricky. For instance, subq $0x80, %rsp and
210 * subq $0x78, %rsp can result in two instructions with different
211 * op-code lengths.
212 * Therefore we align the interrupt handlers.
213 */
214
215 .iflt \i-32
216 .if (1 << \i) & ERROR_WORD_INTERRUPT_LIST
217 /*
218 * Version with error word.
219 */
220 subq $ISTATE_SOFT_SIZE, %rsp
221 .else
222 /*
223 * Version without error word.
224 */
225 subq $(ISTATE_SOFT_SIZE + 8), %rsp
226 .endif
227 .else
228 /*
229 * Version without error word.
230 */
231 subq $(ISTATE_SOFT_SIZE + 8), %rsp
232 .endif
233
234 /*
235 * Save the general purpose registers.
236 */
237 movq %rax, ISTATE_OFFSET_RAX(%rsp)
238 movq %rbx, ISTATE_OFFSET_RBX(%rsp)
239 movq %rcx, ISTATE_OFFSET_RCX(%rsp)
240 movq %rdx, ISTATE_OFFSET_RDX(%rsp)
241 movq %rsi, ISTATE_OFFSET_RSI(%rsp)
242 movq %rdi, ISTATE_OFFSET_RDI(%rsp)
243 movq %rbp, ISTATE_OFFSET_RBP(%rsp)
244 movq %r8, ISTATE_OFFSET_R8(%rsp)
245 movq %r9, ISTATE_OFFSET_R9(%rsp)
246 movq %r10, ISTATE_OFFSET_R10(%rsp)
247 movq %r11, ISTATE_OFFSET_R11(%rsp)
248 movq %r12, ISTATE_OFFSET_R12(%rsp)
249 movq %r13, ISTATE_OFFSET_R13(%rsp)
250 movq %r14, ISTATE_OFFSET_R14(%rsp)
251 movq %r15, ISTATE_OFFSET_R15(%rsp)
252
253 /*
254 * Imitate a regular stack frame linkage.
255 * Stop stack traces here if we came from userspace.
256 */
257 xorq %rdx, %rdx
258 cmpq $(gdtselector(KTEXT_DES)), ISTATE_OFFSET_CS(%rsp)
259 cmovnzq %rdx, %rbp
260
261 movq %rbp, ISTATE_OFFSET_RBP_FRAME(%rsp)
262 movq ISTATE_OFFSET_RIP(%rsp), %rax
263 movq %rax, ISTATE_OFFSET_RIP_FRAME(%rsp)
264 leaq ISTATE_OFFSET_RBP_FRAME(%rsp), %rbp
265
266 movq $(\i), %rdi /* pass intnum in the first argument */
267 movq %rsp, %rsi /* pass istate address in the second argument */
268
269 cld
270
271 /* Call exc_dispatch(i, istate) */
272 call exc_dispatch
273
274 /*
275 * Restore all scratch registers and the preserved registers we have
276 * clobbered in this handler (i.e. RBP).
277 */
278 movq ISTATE_OFFSET_RAX(%rsp), %rax
279 movq ISTATE_OFFSET_RCX(%rsp), %rcx
280 movq ISTATE_OFFSET_RDX(%rsp), %rdx
281 movq ISTATE_OFFSET_RSI(%rsp), %rsi
282 movq ISTATE_OFFSET_RDI(%rsp), %rdi
283 movq ISTATE_OFFSET_RBP(%rsp), %rbp
284 movq ISTATE_OFFSET_R8(%rsp), %r8
285 movq ISTATE_OFFSET_R9(%rsp), %r9
286 movq ISTATE_OFFSET_R10(%rsp), %r10
287 movq ISTATE_OFFSET_R11(%rsp), %r11
288
289 /* $8 = Skip error word */
290 addq $(ISTATE_SOFT_SIZE + 8), %rsp
291 iretq
292
293 .align INTERRUPT_ALIGN
294 .if (\n - \i) - 1
295 handler "(\i + 1)", \n
296 .endif
297.endm
298
299.align INTERRUPT_ALIGN
300interrupt_handlers:
301 h_start:
302 handler 0 IDT_ITEMS
303 h_end:
304
305/** Low-level syscall handler
306 *
307 * Registers on entry:
308 *
309 * @param %rcx Userspace return address.
310 * @param %r11 Userspace RLFAGS.
311 *
312 * @param %rax Syscall number.
313 * @param %rdi 1st syscall argument.
314 * @param %rsi 2nd syscall argument.
315 * @param %rdx 3rd syscall argument.
316 * @param %r10 4th syscall argument. Used instead of RCX because
317 * the SYSCALL instruction clobbers it.
318 * @param %r8 5th syscall argument.
319 * @param %r9 6th syscall argument.
320 *
321 * @return Return value is in %rax.
322 *
323 */
324syscall_entry:
325 /* Switch to hidden %gs */
326 swapgs
327
328 /*
329 * %gs:0 Scratch space for this thread's user RSP
330 * %gs:8 Address to be used as this thread's kernel RSP
331 */
332
333 movq %rsp, %gs:0 /* save this thread's user RSP */
334 movq %gs:8, %rsp /* set this thread's kernel RSP */
335
336 /*
337 * Note that the space needed for the imitated istate structure has been
338 * preallocated for us in thread_create_arch() and set in
339 * before_thread_runs_arch().
340 */
341
342 /*
343 * Save the general purpose registers and push the 7th argument (syscall
344 * number) onto the stack. Note that the istate structure has a layout
345 * which supports this.
346 */
347 movq %rax, ISTATE_OFFSET_RAX(%rsp) /* 7th argument, passed on stack */
348 movq %rbx, ISTATE_OFFSET_RBX(%rsp) /* observability */
349 movq %rcx, ISTATE_OFFSET_RCX(%rsp) /* userspace RIP */
350 movq %rdx, ISTATE_OFFSET_RDX(%rsp) /* 3rd argument, observability */
351 movq %rsi, ISTATE_OFFSET_RSI(%rsp) /* 2nd argument, observability */
352 movq %rdi, ISTATE_OFFSET_RDI(%rsp) /* 1st argument, observability */
353 movq %rbp, ISTATE_OFFSET_RBP(%rsp) /* need to preserve userspace RBP */
354 movq %r8, ISTATE_OFFSET_R8(%rsp) /* 5th argument, observability */
355 movq %r9, ISTATE_OFFSET_R9(%rsp) /* 6th argument, observability */
356 movq %r10, ISTATE_OFFSET_R10(%rsp) /* 4th argument, observability */
357 movq %r11, ISTATE_OFFSET_R11(%rsp) /* low 32 bits userspace RFLAGS */
358 movq %r12, ISTATE_OFFSET_R12(%rsp) /* observability */
359 movq %r13, ISTATE_OFFSET_R13(%rsp) /* observability */
360 movq %r14, ISTATE_OFFSET_R14(%rsp) /* observability */
361 movq %r15, ISTATE_OFFSET_R15(%rsp) /* observability */
362
363 /*
364 * Save the return address and the userspace stack on locations that
365 * would normally be taken by them.
366 */
367 movq %gs:0, %rax
368 movq %rax, ISTATE_OFFSET_RSP(%rsp)
369 movq %rcx, ISTATE_OFFSET_RIP(%rsp)
370
371 /*
372 * Imitate a regular stack frame linkage.
373 */
374 movq $0, ISTATE_OFFSET_RBP_FRAME(%rsp)
375 movq %rcx, ISTATE_OFFSET_RIP_FRAME(%rsp)
376 leaq ISTATE_OFFSET_RBP_FRAME(%rsp), %rbp
377
378 /* Switch back to normal %gs */
379 swapgs
380 sti
381
382 /* Copy the 4th argument where it is expected */
383 movq %r10, %rcx
384
385 /*
386 * Call syscall_handler() with the 7th argument passed on stack.
387 */
388 call syscall_handler
389
390 cli
391
392 /*
393 * Restore registers needed for return via the SYSRET instruction and
394 * the clobbered preserved registers (i.e. RBP).
395 */
396 movq ISTATE_OFFSET_RBP(%rsp), %rbp
397 movq ISTATE_OFFSET_RCX(%rsp), %rcx
398 movq ISTATE_OFFSET_R11(%rsp), %r11
399 movq ISTATE_OFFSET_RSP(%rsp), %rsp
400
401 sysretq
402
403/** Print Unicode character to EGA display.
404 *
405 * If CONFIG_EGA is undefined or CONFIG_FB is defined
406 * then this function does nothing.
407 *
408 * Since the EGA can only display Extended ASCII (usually
409 * ISO Latin 1) characters, some of the Unicode characters
410 * can be displayed in a wrong way. Only newline and backspace
411 * are interpreted, all other characters (even unprintable) are
412 * printed verbatim.
413 *
414 * @param %rdi Unicode character to be printed.
415 *
416 */
417early_putchar:
418
419#if ((defined(CONFIG_EGA)) && (!defined(CONFIG_FB)))
420
421 /* Prologue, save preserved registers */
422 pushq %rbp
423 movq %rsp, %rbp
424 pushq %rbx
425
426 movq %rdi, %rsi
427 movq $(PA2KA(0xb8000)), %rdi /* base of EGA text mode memory */
428 xorq %rax, %rax
429
430 /* Read bits 8 - 15 of the cursor address */
431 movw $0x3d4, %dx
432 movb $0xe, %al
433 outb %al, %dx
434
435 movw $0x3d5, %dx
436 inb %dx, %al
437 shl $8, %ax
438
439 /* Read bits 0 - 7 of the cursor address */
440 movw $0x3d4, %dx
441 movb $0xf, %al
442 outb %al, %dx
443
444 movw $0x3d5, %dx
445 inb %dx, %al
446
447 /* Sanity check for the cursor on screen */
448 cmp $2000, %ax
449 jb early_putchar_cursor_ok
450
451 movw $1998, %ax
452
453 early_putchar_cursor_ok:
454
455 movw %ax, %bx
456 shl $1, %rax
457 addq %rax, %rdi
458
459 movq %rsi, %rax
460
461 cmp $0x0a, %al
462 jne early_putchar_backspace
463
464 /* Interpret newline */
465
466 movw %bx, %ax /* %bx -> %dx:%ax */
467 xorw %dx, %dx
468
469 movw $80, %cx
470 idivw %cx, %ax /* %dx = %bx % 80 */
471
472 /* %bx <- %bx + 80 - (%bx % 80) */
473 addw %cx, %bx
474 subw %dx, %bx
475
476 jmp early_putchar_skip
477
478 early_putchar_backspace:
479
480 cmp $0x08, %al
481 jne early_putchar_print
482
483 /* Interpret backspace */
484
485 cmp $0x0000, %bx
486 je early_putchar_skip
487
488 dec %bx
489 jmp early_putchar_skip
490
491 early_putchar_print:
492
493 /* Print character */
494
495 movb $0x0e, %ah /* black background, yellow foreground */
496 stosw
497 inc %bx
498
499 early_putchar_skip:
500
501 /* Sanity check for the cursor on the last line */
502 cmp $2000, %bx
503 jb early_putchar_no_scroll
504
505 /* Scroll the screen (24 rows) */
506 movq $(PA2KA(0xb80a0)), %rsi
507 movq $(PA2KA(0xb8000)), %rdi
508 movq $480, %rcx
509 rep movsq
510
511 /* Clear the 24th row */
512 xorq %rax, %rax
513 movq $20, %rcx
514 rep stosq
515
516 /* Go to row 24 */
517 movw $1920, %bx
518
519 early_putchar_no_scroll:
520
521 /* Write bits 8 - 15 of the cursor address */
522 movw $0x3d4, %dx
523 movb $0xe, %al
524 outb %al, %dx
525
526 movw $0x3d5, %dx
527 movb %bh, %al
528 outb %al, %dx
529
530 /* Write bits 0 - 7 of the cursor address */
531 movw $0x3d4, %dx
532 movb $0xf, %al
533 outb %al, %dx
534
535 movw $0x3d5, %dx
536 movb %bl, %al
537 outb %al, %dx
538
539 /* Epilogue, restore preserved registers */
540 popq %rbx
541 leave
542
543#endif
544
545 ret
546
547.data
548.global interrupt_handler_size
549
550interrupt_handler_size: .quad (h_end - h_start) / IDT_ITEMS
Note: See TracBrowser for help on using the repository browser.