source: mainline/kernel/arch/amd64/src/asm.S@ 1d3d2cf

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 1d3d2cf was 1d3d2cf, checked in by Martin Decky <martin@…>, 15 years ago

rename gdtselector to GDT_SELECTOR to make explicit it is a macro
unify how bootstrap_gdtr is defined on amd64 and ia32
  • Property mode set to 100644
File size: 12.6 KB
Line 
1/*
2 * Copyright (c) 2005 Ondrej Palkovsky
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *
9 * - Redistributions of source code must retain the above copyright
10 * notice, this list of conditions and the following disclaimer.
11 * - Redistributions in binary form must reproduce the above copyright
12 * notice, this list of conditions and the following disclaimer in the
13 * documentation and/or other materials provided with the distribution.
14 * - The name of the author may not be used to endorse or promote products
15 * derived from this software without specific prior written permission.
16 *
17 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27 */
28
29#include <arch/pm.h>
30#include <arch/mm/page.h>
31
32.text
33.global interrupt_handlers
34.global syscall_entry
35.global cpuid
36.global has_cpuid
37.global read_efer_flag
38.global set_efer_flag
39.global memsetb
40.global memsetw
41.global memcpy
42.global memcpy_from_uspace
43.global memcpy_to_uspace
44.global memcpy_from_uspace_failover_address
45.global memcpy_to_uspace_failover_address
46.global early_putchar
47
48/* Wrapper for generic memsetb */
49memsetb:
50 jmp _memsetb
51
52/* Wrapper for generic memsetw */
53memsetw:
54 jmp _memsetw
55
56#define MEMCPY_DST %rdi
57#define MEMCPY_SRC %rsi
58#define MEMCPY_SIZE %rdx
59
60/**
61 * Copy memory from/to userspace.
62 *
63 * This is almost conventional memcpy().
64 * The difference is that there is a failover part
65 * to where control is returned from a page fault if
66 * the page fault occurs during copy_from_uspace()
67 * or copy_to_uspace().
68 *
69 * @param MEMCPY_DST Destination address.
70 * @param MEMCPY_SRC Source address.
71 * @param MEMCPY_SIZE Number of bytes to copy.
72 *
73 * @retrun MEMCPY_DST on success, 0 on failure.
74 *
75 */
76memcpy:
77memcpy_from_uspace:
78memcpy_to_uspace:
79 movq MEMCPY_DST, %rax
80
81 movq MEMCPY_SIZE, %rcx
82 shrq $3, %rcx /* size / 8 */
83
84 rep movsq /* copy as much as possible word by word */
85
86 movq MEMCPY_SIZE, %rcx
87 andq $7, %rcx /* size % 8 */
88 jz 0f
89
90 rep movsb /* copy the rest byte by byte */
91
92 0:
93 ret /* return MEMCPY_SRC, success */
94
95memcpy_from_uspace_failover_address:
96memcpy_to_uspace_failover_address:
97 xorq %rax, %rax /* return 0, failure */
98 ret
99
100/** Determine CPUID support
101*
102* @return 0 in EAX if CPUID is not support, 1 if supported.
103*
104*/
105has_cpuid:
106 /* Load RFLAGS */
107 pushfq
108 popq %rax
109 movq %rax, %rdx
110
111 /* Flip the ID bit */
112 btcl $21, %edx
113
114 /* Store RFLAGS */
115 pushq %rdx
116 popfq
117 pushfq
118
119 /* Get the ID bit again */
120 popq %rdx
121 andl $(1 << 21), %eax
122 andl $(1 << 21), %edx
123
124 /* 0 if not supported, 1 if supported */
125 xorl %edx, %eax
126 ret
127
128cpuid:
129 /* Preserve %rbx across function calls */
130 movq %rbx, %r10
131
132 /* Load the command into %eax */
133 movl %edi, %eax
134
135 cpuid
136 movl %eax, 0(%rsi)
137 movl %ebx, 4(%rsi)
138 movl %ecx, 8(%rsi)
139 movl %edx, 12(%rsi)
140
141 movq %r10, %rbx
142 ret
143
144set_efer_flag:
145 movq $0xc0000080, %rcx
146 rdmsr
147 btsl %edi, %eax
148 wrmsr
149 ret
150
151read_efer_flag:
152 movq $0xc0000080, %rcx
153 rdmsr
154 ret
155
156#define ISTATE_OFFSET_RAX 0
157#define ISTATE_OFFSET_RBX 8
158#define ISTATE_OFFSET_RCX 16
159#define ISTATE_OFFSET_RDX 24
160#define ISTATE_OFFSET_RSI 32
161#define ISTATE_OFFSET_RDI 40
162#define ISTATE_OFFSET_RBP 48
163#define ISTATE_OFFSET_R8 56
164#define ISTATE_OFFSET_R9 64
165#define ISTATE_OFFSET_R10 72
166#define ISTATE_OFFSET_R11 80
167#define ISTATE_OFFSET_R12 88
168#define ISTATE_OFFSET_R13 96
169#define ISTATE_OFFSET_R14 104
170#define ISTATE_OFFSET_R15 112
171#define ISTATE_OFFSET_ALIGNMENT 120
172#define ISTATE_OFFSET_RBP_FRAME 128
173#define ISTATE_OFFSET_RIP_FRAME 136
174#define ISTATE_OFFSET_ERROR_WORD 144
175#define ISTATE_OFFSET_RIP 152
176#define ISTATE_OFFSET_CS 160
177#define ISTATE_OFFSET_RFLAGS 168
178#define ISTATE_OFFSET_RSP 176
179#define ISTATE_OFFSET_SS 184
180
181/*
182 * Size of the istate structure without the hardware-saved part and without the
183 * error word.
184 */
185#define ISTATE_SOFT_SIZE 144
186
187/**
188 * Mask for interrupts 0 - 31 (bits 0 - 31) where 0 means that int
189 * has no error word and 1 means interrupt with error word
190 *
191 */
192#define ERROR_WORD_INTERRUPT_LIST 0x00027D00
193
194.macro handler i
195.global int_\i
196int_\i:
197
198 /*
199 * Choose between version with error code and version without error
200 * code.
201 */
202
203 .iflt \i-32
204 .if (1 << \i) & ERROR_WORD_INTERRUPT_LIST
205 /*
206 * Version with error word.
207 */
208 subq $ISTATE_SOFT_SIZE, %rsp
209 .else
210 /*
211 * Version without error word.
212 */
213 subq $(ISTATE_SOFT_SIZE + 8), %rsp
214 .endif
215 .else
216 /*
217 * Version without error word.
218 */
219 subq $(ISTATE_SOFT_SIZE + 8), %rsp
220 .endif
221
222 /*
223 * Save the general purpose registers.
224 */
225 movq %rax, ISTATE_OFFSET_RAX(%rsp)
226 movq %rbx, ISTATE_OFFSET_RBX(%rsp)
227 movq %rcx, ISTATE_OFFSET_RCX(%rsp)
228 movq %rdx, ISTATE_OFFSET_RDX(%rsp)
229 movq %rsi, ISTATE_OFFSET_RSI(%rsp)
230 movq %rdi, ISTATE_OFFSET_RDI(%rsp)
231 movq %rbp, ISTATE_OFFSET_RBP(%rsp)
232 movq %r8, ISTATE_OFFSET_R8(%rsp)
233 movq %r9, ISTATE_OFFSET_R9(%rsp)
234 movq %r10, ISTATE_OFFSET_R10(%rsp)
235 movq %r11, ISTATE_OFFSET_R11(%rsp)
236 movq %r12, ISTATE_OFFSET_R12(%rsp)
237 movq %r13, ISTATE_OFFSET_R13(%rsp)
238 movq %r14, ISTATE_OFFSET_R14(%rsp)
239 movq %r15, ISTATE_OFFSET_R15(%rsp)
240
241 /*
242 * Imitate a regular stack frame linkage.
243 * Stop stack traces here if we came from userspace.
244 */
245 xorq %rdx, %rdx
246 cmpq $(GDT_SELECTOR(KTEXT_DES)), ISTATE_OFFSET_CS(%rsp)
247 cmovnzq %rdx, %rbp
248
249 movq %rbp, ISTATE_OFFSET_RBP_FRAME(%rsp)
250 movq ISTATE_OFFSET_RIP(%rsp), %rax
251 movq %rax, ISTATE_OFFSET_RIP_FRAME(%rsp)
252 leaq ISTATE_OFFSET_RBP_FRAME(%rsp), %rbp
253
254 movq $(\i), %rdi /* pass intnum in the first argument */
255 movq %rsp, %rsi /* pass istate address in the second argument */
256
257 cld
258
259 /* Call exc_dispatch(i, istate) */
260 call exc_dispatch
261
262 /*
263 * Restore all scratch registers and the preserved registers we have
264 * clobbered in this handler (i.e. RBP).
265 */
266 movq ISTATE_OFFSET_RAX(%rsp), %rax
267 movq ISTATE_OFFSET_RCX(%rsp), %rcx
268 movq ISTATE_OFFSET_RDX(%rsp), %rdx
269 movq ISTATE_OFFSET_RSI(%rsp), %rsi
270 movq ISTATE_OFFSET_RDI(%rsp), %rdi
271 movq ISTATE_OFFSET_RBP(%rsp), %rbp
272 movq ISTATE_OFFSET_R8(%rsp), %r8
273 movq ISTATE_OFFSET_R9(%rsp), %r9
274 movq ISTATE_OFFSET_R10(%rsp), %r10
275 movq ISTATE_OFFSET_R11(%rsp), %r11
276
277 /* $8 = Skip error word */
278 addq $(ISTATE_SOFT_SIZE + 8), %rsp
279 iretq
280.endm
281
282#define LIST_0_63 \
283 0, 1, 2, 3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,\
284 28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,\
285 53,54,55,56,57,58,59,60,61,62,63
286
287interrupt_handlers:
288.irp cnt, LIST_0_63
289 handler \cnt
290.endr
291
292/** Low-level syscall handler
293 *
294 * Registers on entry:
295 *
296 * @param %rcx Userspace return address.
297 * @param %r11 Userspace RLFAGS.
298 *
299 * @param %rax Syscall number.
300 * @param %rdi 1st syscall argument.
301 * @param %rsi 2nd syscall argument.
302 * @param %rdx 3rd syscall argument.
303 * @param %r10 4th syscall argument. Used instead of RCX because
304 * the SYSCALL instruction clobbers it.
305 * @param %r8 5th syscall argument.
306 * @param %r9 6th syscall argument.
307 *
308 * @return Return value is in %rax.
309 *
310 */
311syscall_entry:
312 /* Switch to hidden %gs */
313 swapgs
314
315 /*
316 * %gs:0 Scratch space for this thread's user RSP
317 * %gs:8 Address to be used as this thread's kernel RSP
318 */
319
320 movq %rsp, %gs:0 /* save this thread's user RSP */
321 movq %gs:8, %rsp /* set this thread's kernel RSP */
322
323 /*
324 * Note that the space needed for the imitated istate structure has been
325 * preallocated for us in thread_create_arch() and set in
326 * before_thread_runs_arch().
327 */
328
329 /*
330 * Save the general purpose registers and push the 7th argument (syscall
331 * number) onto the stack. Note that the istate structure has a layout
332 * which supports this.
333 */
334 movq %rax, ISTATE_OFFSET_RAX(%rsp) /* 7th argument, passed on stack */
335 movq %rbx, ISTATE_OFFSET_RBX(%rsp) /* observability */
336 movq %rcx, ISTATE_OFFSET_RCX(%rsp) /* userspace RIP */
337 movq %rdx, ISTATE_OFFSET_RDX(%rsp) /* 3rd argument, observability */
338 movq %rsi, ISTATE_OFFSET_RSI(%rsp) /* 2nd argument, observability */
339 movq %rdi, ISTATE_OFFSET_RDI(%rsp) /* 1st argument, observability */
340 movq %rbp, ISTATE_OFFSET_RBP(%rsp) /* need to preserve userspace RBP */
341 movq %r8, ISTATE_OFFSET_R8(%rsp) /* 5th argument, observability */
342 movq %r9, ISTATE_OFFSET_R9(%rsp) /* 6th argument, observability */
343 movq %r10, ISTATE_OFFSET_R10(%rsp) /* 4th argument, observability */
344 movq %r11, ISTATE_OFFSET_R11(%rsp) /* low 32 bits userspace RFLAGS */
345 movq %r12, ISTATE_OFFSET_R12(%rsp) /* observability */
346 movq %r13, ISTATE_OFFSET_R13(%rsp) /* observability */
347 movq %r14, ISTATE_OFFSET_R14(%rsp) /* observability */
348 movq %r15, ISTATE_OFFSET_R15(%rsp) /* observability */
349
350 /*
351 * Save the return address and the userspace stack on locations that
352 * would normally be taken by them.
353 */
354 movq %gs:0, %rax
355 movq %rax, ISTATE_OFFSET_RSP(%rsp)
356 movq %rcx, ISTATE_OFFSET_RIP(%rsp)
357
358 /*
359 * Imitate a regular stack frame linkage.
360 */
361 movq $0, ISTATE_OFFSET_RBP_FRAME(%rsp)
362 movq %rcx, ISTATE_OFFSET_RIP_FRAME(%rsp)
363 leaq ISTATE_OFFSET_RBP_FRAME(%rsp), %rbp
364
365 /* Switch back to normal %gs */
366 swapgs
367 sti
368
369 /* Copy the 4th argument where it is expected */
370 movq %r10, %rcx
371
372 /*
373 * Call syscall_handler() with the 7th argument passed on stack.
374 */
375 call syscall_handler
376
377 cli
378
379 /*
380 * Restore registers needed for return via the SYSRET instruction and
381 * the clobbered preserved registers (i.e. RBP).
382 */
383 movq ISTATE_OFFSET_RBP(%rsp), %rbp
384 movq ISTATE_OFFSET_RCX(%rsp), %rcx
385 movq ISTATE_OFFSET_R11(%rsp), %r11
386 movq ISTATE_OFFSET_RSP(%rsp), %rsp
387
388 sysretq
389
390/** Print Unicode character to EGA display.
391 *
392 * If CONFIG_EGA is undefined or CONFIG_FB is defined
393 * then this function does nothing.
394 *
395 * Since the EGA can only display Extended ASCII (usually
396 * ISO Latin 1) characters, some of the Unicode characters
397 * can be displayed in a wrong way. Only newline and backspace
398 * are interpreted, all other characters (even unprintable) are
399 * printed verbatim.
400 *
401 * @param %rdi Unicode character to be printed.
402 *
403 */
404early_putchar:
405
406#if ((defined(CONFIG_EGA)) && (!defined(CONFIG_FB)))
407
408 /* Prologue, save preserved registers */
409 pushq %rbp
410 movq %rsp, %rbp
411 pushq %rbx
412
413 movq %rdi, %rsi
414 movq $(PA2KA(0xb8000)), %rdi /* base of EGA text mode memory */
415 xorq %rax, %rax
416
417 /* Read bits 8 - 15 of the cursor address */
418 movw $0x3d4, %dx
419 movb $0xe, %al
420 outb %al, %dx
421
422 movw $0x3d5, %dx
423 inb %dx, %al
424 shl $8, %ax
425
426 /* Read bits 0 - 7 of the cursor address */
427 movw $0x3d4, %dx
428 movb $0xf, %al
429 outb %al, %dx
430
431 movw $0x3d5, %dx
432 inb %dx, %al
433
434 /* Sanity check for the cursor on screen */
435 cmp $2000, %ax
436 jb early_putchar_cursor_ok
437
438 movw $1998, %ax
439
440 early_putchar_cursor_ok:
441
442 movw %ax, %bx
443 shl $1, %rax
444 addq %rax, %rdi
445
446 movq %rsi, %rax
447
448 cmp $0x0a, %al
449 jne early_putchar_backspace
450
451 /* Interpret newline */
452
453 movw %bx, %ax /* %bx -> %dx:%ax */
454 xorw %dx, %dx
455
456 movw $80, %cx
457 idivw %cx, %ax /* %dx = %bx % 80 */
458
459 /* %bx <- %bx + 80 - (%bx % 80) */
460 addw %cx, %bx
461 subw %dx, %bx
462
463 jmp early_putchar_skip
464
465 early_putchar_backspace:
466
467 cmp $0x08, %al
468 jne early_putchar_print
469
470 /* Interpret backspace */
471
472 cmp $0x0000, %bx
473 je early_putchar_skip
474
475 dec %bx
476 jmp early_putchar_skip
477
478 early_putchar_print:
479
480 /* Print character */
481
482 movb $0x0e, %ah /* black background, yellow foreground */
483 stosw
484 inc %bx
485
486 early_putchar_skip:
487
488 /* Sanity check for the cursor on the last line */
489 cmp $2000, %bx
490 jb early_putchar_no_scroll
491
492 /* Scroll the screen (24 rows) */
493 movq $(PA2KA(0xb80a0)), %rsi
494 movq $(PA2KA(0xb8000)), %rdi
495 movq $480, %rcx
496 rep movsq
497
498 /* Clear the 24th row */
499 xorq %rax, %rax
500 movq $20, %rcx
501 rep stosq
502
503 /* Go to row 24 */
504 movw $1920, %bx
505
506 early_putchar_no_scroll:
507
508 /* Write bits 8 - 15 of the cursor address */
509 movw $0x3d4, %dx
510 movb $0xe, %al
511 outb %al, %dx
512
513 movw $0x3d5, %dx
514 movb %bh, %al
515 outb %al, %dx
516
517 /* Write bits 0 - 7 of the cursor address */
518 movw $0x3d4, %dx
519 movb $0xf, %al
520 outb %al, %dx
521
522 movw $0x3d5, %dx
523 movb %bl, %al
524 outb %al, %dx
525
526 /* Epilogue, restore preserved registers */
527 popq %rbx
528 leave
529
530#endif
531
532 ret
533
Note: See TracBrowser for help on using the repository browser.