source: mainline/arch/ia32/src/context.s@ f5075fa

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since f5075fa was f761f1eb, checked in by Jakub Jermar <jakub@…>, 21 years ago

Initial import

  • Property mode set to 100644
File size: 2.4 KB
Line 
1#
2# Copyright (C) 2001-2004 Jakub Jermar
3# All rights reserved.
4#
5# Redistribution and use in source and binary forms, with or without
6# modification, are permitted provided that the following conditions
7# are met:
8#
9# - Redistributions of source code must retain the above copyright
10# notice, this list of conditions and the following disclaimer.
11# - Redistributions in binary form must reproduce the above copyright
12# notice, this list of conditions and the following disclaimer in the
13# documentation and/or other materials provided with the distribution.
14# - The name of the author may not be used to endorse or promote products
15# derived from this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27#
28
29.text
30
31.global context_save
32.global context_restore
33
34#
35# save context of this CPU
36context_save:
37 push %ebx
38
39 movl 4(%esp),%eax # the caller's return %eip
40 movl 8(%esp),%ebx # address of the kernel_context variable to save context to
41 movl %eax,4(%ebx) # %eip -> ctx->pc
42 movl %esp,(%ebx) # %esp -> ctx->sp
43
44 movl %ebx,%eax
45 pop %ebx
46
47 movl %ebx,8(%eax)
48 movl %ecx,12(%eax)
49 movl %edx,16(%eax)
50 movl %esi,20(%eax)
51 movl %edi,24(%eax)
52 movl %ebp,28(%eax)
53
54 xorl %eax,%eax # context_save returns 1
55 incl %eax
56 ret
57
58#
59# restore saved context on this CPU
60context_restore:
61 movl 4(%esp),%eax # address of the kernel_context variable to restore context from
62 movl (%eax),%esp # ctx->sp -> %esp
63 addl $4,%esp # this is for the pop we don't do
64
65 movl 8(%eax),%ebx
66 movl 12(%eax),%ecx
67 movl 16(%eax),%edx
68 movl 20(%eax),%esi
69 movl 24(%eax),%edi
70 movl 28(%eax),%ebp
71
72 movl 4(%eax),%eax
73 movl %eax,(%esp) # ctx->pc -> saver's return %eip
74 xorl %eax,%eax # context_restore returns 0
75 ret
Note: See TracBrowser for help on using the repository browser.