source: mainline/arch/ia32/src/boot/boot.S@ a5556b4

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since a5556b4 was b1cf98c, checked in by Jakub Jermar <jakub@…>, 20 years ago

Documentation updates for amd64, mips32 and ia32.

Replace %L with %P printf() formatter in MPS and ACPI detection functions to print addresses in maximal width.

Tweak memmap.S and IA-32 and AMd64 boot.S.
Cancel unneeded instructions.
Replace cmpl $0, %ebx with testl %ebx, %ebx.
Move memmap.S data to K_DATA_START section.
  • Property mode set to 100644
File size: 6.0 KB
Line 
1#
2# Copyright (C) 2001-2004 Jakub Jermar
3# All rights reserved.
4#
5# Redistribution and use in source and binary forms, with or without
6# modification, are permitted provided that the following conditions
7# are met:
8#
9# - Redistributions of source code must retain the above copyright
10# notice, this list of conditions and the following disclaimer.
11# - Redistributions in binary form must reproduce the above copyright
12# notice, this list of conditions and the following disclaimer in the
13# documentation and/or other materials provided with the distribution.
14# - The name of the author may not be used to endorse or promote products
15# derived from this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27#
28
29#define __ASM__
30
31#include <arch/boot/boot.h>
32#include <arch/boot/memmapasm.h>
33#include <arch/mm/page.h>
34#include <arch/pm.h>
35
36.section K_TEXT_START
37.global kernel_image_start
38
39KTEXT=8
40KDATA=16
41
42.code16
43#
44# This is where we require any SPARTAN-kernel-compatible boot loader
45# to pass control in real mode.
46#
47# Protected mode tables are statically initialised during compile
48# time. So we can just load the respective table registers and
49# switch to protected mode.
50#
51kernel_image_start:
52 cli
53 xorw %ax, %ax
54 movw %ax, %ds
55 movw %ax, %es
56 movw %ax, %ss # initialize stack segment register
57 movl $BOOTSTRAP_OFFSET - 0x400, %esp # initialize stack pointer
58
59 call memmap_arch_init
60
61 lgdt real_bootstrap_gdtr_boot # initialize Global Descriptor Table register
62
63 movl %cr0, %eax
64 orl $0x1, %eax
65 movl %eax, %cr0 # switch to protected mode
66
67 jmpl $KTEXT, $boot_image_start
68
69.code32
70.align 4
71multiboot_header:
72 .long MULTIBOOT_HEADER_MAGIC
73 .long MULTIBOOT_HEADER_FLAGS
74 .long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
75 .long multiboot_header + BOOT_OFFSET
76 .long unmapped_ktext_start + BOOT_OFFSET
77 .long 0
78 .long 0
79 .long multiboot_image_start + BOOT_OFFSET
80
81boot_image_start:
82 movw $KDATA, %ax
83 movw %ax, %es
84 movw %ax, %gs
85 movw %ax, %fs
86 movw %ax, %ds # kernel data + stack
87 movw %ax, %ss
88
89 movb $0xd1, %al # enable A20 using i8042 controller
90 outb %al, $0x64
91 movb $0xdf, %al
92 outb %al, $0x60
93
94 movl $BOOTSTRAP_OFFSET, %esi
95 movl $BOOTSTRAP_OFFSET + BOOT_OFFSET, %edi
96 movl $_hardcoded_kernel_size, %ecx
97 cld
98 rep movsb
99
100 call map_kernel # map kernel and turn paging on
101
102 call main_bsp # never returns
103
104 cli
105 hlt
106
107multiboot_image_start:
108 movl $BOOTSTRAP_OFFSET - 0x400, %esp # initialize stack pointer
109
110 lgdt protected_bootstrap_gdtr - 0x80000000 # initialize Global Descriptor Table register
111
112 movw $KDATA, %cx
113 movw %cx, %es
114 movw %cx, %gs
115 movw %cx, %fs
116 movw %cx, %ds # kernel data + stack
117 movw %cx, %ss
118
119 jmpl $KTEXT, $multiboot_meeting_point + BOOT_OFFSET
120 multiboot_meeting_point:
121
122 pushl %ebx # save parameters from GRUB
123 pushl %eax
124
125 movl $BOOTSTRAP_OFFSET + BOOT_OFFSET, %esi
126 movl $BOOTSTRAP_OFFSET, %edi
127 movl $_hardcoded_unmapped_size, %ecx
128 cld
129 rep movsb
130
131 call map_kernel # map kernel and turn paging on
132
133 popl %eax
134 popl %ebx
135 cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
136 je valid_boot
137
138 xorl %ecx, %ecx # no memory size or map available
139 movl %ecx, e801memorysize
140 movl %ecx, e820counter
141
142 jmp invalid_boot
143
144 valid_boot:
145
146 movl (%ebx), %eax # ebx = physical address of struct multiboot_info
147
148 bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
149 jc mem_valid
150
151 xorl %ecx, %ecx
152 jmp mem_invalid
153
154 mem_valid:
155 movl 4(%ebx), %ecx # mbi->mem_lower
156 addl 8(%ebx), %ecx # mbi->mem_upper
157
158 mem_invalid:
159 movl %ecx, e801memorysize
160
161 bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
162 jc mmap_valid
163
164 xorl %edx, %edx
165 jmp mmap_invalid
166
167 mmap_valid:
168 movl 44(%ebx), %ecx # mbi->mmap_length
169 movl 48(%ebx), %esi # mbi->mmap_addr
170 movl $e820table, %edi
171 xorl %edx, %edx
172
173 mmap_loop:
174 cmpl $0, %ecx
175 jle mmap_end
176
177 movl 4(%esi), %eax # mmap->base_addr_low
178 movl %eax, (%edi)
179
180 movl 8(%esi), %eax # mmap->base_addr_high
181 movl %eax, 4(%edi)
182
183 movl 12(%esi), %eax # mmap->length_low
184 movl %eax, 8(%edi)
185
186 movl 16(%esi), %eax # mmap->length_high
187 movl %eax, 12(%edi)
188
189 movl 20(%esi), %eax # mmap->type
190 movl %eax, 16(%edi)
191
192 movl (%esi), %eax # mmap->size
193 addl $0x4, %eax
194 addl %eax, %esi
195 subl %eax, %ecx
196 addl $MEMMAP_E820_RECORD_SIZE, %edi
197 incl %edx
198 jmp mmap_loop
199
200 mmap_end:
201
202 mmap_invalid:
203 movl %edx, e820counter
204
205 invalid_boot:
206
207 call main_bsp - BOOT_OFFSET # never returns
208
209 cli
210 hlt
211
212.global map_kernel
213map_kernel:
214 #
215 # Here we setup mapping for both the unmapped and mapped sections of the kernel.
216 # For simplicity, we set only one 4M page for 0x00000000 and one for 0x80000000.
217 #
218 movl %cr4, %ecx
219 orl $(1<<4), %ecx
220 movl %ecx, %cr4 # turn PSE on
221
222 movl $((1<<7)|(1<<0)), %eax
223 movl %eax, page_directory # mapping 0x00000000 => 0x00000000
224
225 movl $(page_directory+2048), %edx
226 movl %eax, (%edx) # mapping 0x80000000 => 0x00000000
227
228 leal page_directory, %eax
229 movl %eax, %cr3
230
231 # turn paging on
232 movl %cr0, %ebx
233 orl $(1<<31), %ebx
234 movl %ebx, %cr0
235 ret
236
237
238.section K_DATA_START
239
240.align 4096
241page_directory:
242 .space 4096, 0
243
244.global real_bootstrap_gdtr_boot
245real_bootstrap_gdtr_boot:
246 .word selector(GDT_ITEMS)
247 .long KA2PA(gdt)-BOOT_OFFSET
248
Note: See TracBrowser for help on using the repository browser.