source: mainline/arch/ia32/src/boot/boot.S@ 4457455

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 4457455 was aa72859, checked in by Martin Decky <martin@…>, 20 years ago

preparation for init task loading
  • Property mode set to 100644
File size: 6.3 KB
Line 
1#
2# Copyright (C) 2001-2004 Jakub Jermar
3# All rights reserved.
4#
5# Redistribution and use in source and binary forms, with or without
6# modification, are permitted provided that the following conditions
7# are met:
8#
9# - Redistributions of source code must retain the above copyright
10# notice, this list of conditions and the following disclaimer.
11# - Redistributions in binary form must reproduce the above copyright
12# notice, this list of conditions and the following disclaimer in the
13# documentation and/or other materials provided with the distribution.
14# - The name of the author may not be used to endorse or promote products
15# derived from this software without specific prior written permission.
16#
17# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27#
28
29#include <arch/boot/boot.h>
30#include <arch/boot/memmap.h>
31#include <arch/mm/page.h>
32#include <arch/pm.h>
33
34.section K_TEXT_START, "ax"
35.global kernel_image_start
36
37KTEXT=8
38KDATA=16
39
40.code16
41#
42# This is where we require any SPARTAN-kernel-compatible boot loader
43# to pass control in real mode.
44#
45# Protected mode tables are statically initialised during compile
46# time. So we can just load the respective table registers and
47# switch to protected mode.
48#
49kernel_image_start:
50 cli
51 xorw %ax, %ax
52 movw %ax, %ds
53 movw %ax, %es
54 movw %ax, %ss # initialize stack segment register
55 movl $BOOTSTRAP_OFFSET - 0x400, %esp # initialize stack pointer
56
57 call memmap_arch_init
58
59 lgdt real_bootstrap_gdtr_boot # initialize Global Descriptor Table register
60
61 movl %cr0, %eax
62 orl $0x1, %eax
63 movl %eax, %cr0 # switch to protected mode
64
65 jmpl $KTEXT, $boot_image_start
66
67.code32
68.align 4
69multiboot_header:
70 .long MULTIBOOT_HEADER_MAGIC
71 .long MULTIBOOT_HEADER_FLAGS
72 .long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
73 .long multiboot_header + BOOT_OFFSET
74 .long unmapped_ktext_start + BOOT_OFFSET
75 .long 0
76 .long 0
77 .long multiboot_image_start + BOOT_OFFSET
78
79boot_image_start:
80 movw $KDATA, %ax
81 movw %ax, %es
82 movw %ax, %gs
83 movw %ax, %fs
84 movw %ax, %ds # kernel data + stack
85 movw %ax, %ss
86
87 movb $0xd1, %al # enable A20 using i8042 controller
88 outb %al, $0x64
89 movb $0xdf, %al
90 outb %al, $0x60
91
92 movl $BOOTSTRAP_OFFSET, %esi
93 movl $BOOTSTRAP_OFFSET + BOOT_OFFSET, %edi
94 movl $_hardcoded_kernel_size, %ecx
95 cld
96 rep movsb
97
98 call map_kernel # map kernel and turn paging on
99
100 call main_bsp # never returns
101
102 cli
103 hlt
104
105multiboot_image_start:
106 movl $BOOTSTRAP_OFFSET - 0x400, %esp # initialize stack pointer
107
108 lgdt protected_bootstrap_gdtr - 0x80000000 # initialize Global Descriptor Table register
109
110 movw $KDATA, %cx
111 movw %cx, %es
112 movw %cx, %gs
113 movw %cx, %fs
114 movw %cx, %ds # kernel data + stack
115 movw %cx, %ss
116
117 jmpl $KTEXT, $multiboot_meeting_point + BOOT_OFFSET
118 multiboot_meeting_point:
119
120 pushl %ebx # save parameters from GRUB
121 pushl %eax
122
123 movl $BOOTSTRAP_OFFSET + BOOT_OFFSET, %esi
124 movl $BOOTSTRAP_OFFSET, %edi
125 movl $_hardcoded_unmapped_size, %ecx
126 cld
127 rep movsb
128
129 call map_kernel # map kernel and turn paging on
130
131 popl %eax
132 popl %ebx
133 cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
134 je valid_boot
135
136 xorl %ecx, %ecx # no memory size or map available
137 movl %ecx, e801memorysize
138 movl %ecx, e820counter
139
140 jmp invalid_boot
141
142 valid_boot:
143
144 movl (%ebx), %eax # ebx = physical address of struct multiboot_info
145
146 bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
147 jc mem_valid
148
149 xorl %ecx, %ecx
150 jmp mem_invalid
151
152 mem_valid:
153 movl 4(%ebx), %ecx # mbi->mem_lower
154 addl 8(%ebx), %ecx # mbi->mem_upper
155
156 mem_invalid:
157 movl %ecx, e801memorysize
158
159 bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
160 jc mods_valid
161
162 xorl %ecx, %ecx
163 xorl %edx, %edx
164 jmp mods_invalid
165
166 mods_valid:
167
168 mods_invalid:
169 movl %ecx, init_addr
170 movl %edx, init_size
171
172 bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
173 jc mmap_valid
174
175 xorl %edx, %edx
176 jmp mmap_invalid
177
178 mmap_valid:
179 movl 44(%ebx), %ecx # mbi->mmap_length
180 movl 48(%ebx), %esi # mbi->mmap_addr
181 movl $e820table, %edi
182 xorl %edx, %edx
183
184 mmap_loop:
185 cmpl $0, %ecx
186 jle mmap_end
187
188 movl 4(%esi), %eax # mmap->base_addr_low
189 movl %eax, (%edi)
190
191 movl 8(%esi), %eax # mmap->base_addr_high
192 movl %eax, 4(%edi)
193
194 movl 12(%esi), %eax # mmap->length_low
195 movl %eax, 8(%edi)
196
197 movl 16(%esi), %eax # mmap->length_high
198 movl %eax, 12(%edi)
199
200 movl 20(%esi), %eax # mmap->type
201 movl %eax, 16(%edi)
202
203 movl (%esi), %eax # mmap->size
204 addl $0x4, %eax
205 addl %eax, %esi
206 subl %eax, %ecx
207 addl $MEMMAP_E820_RECORD_SIZE, %edi
208 incl %edx
209 jmp mmap_loop
210
211 mmap_end:
212
213 mmap_invalid:
214 movl %edx, e820counter
215
216 invalid_boot:
217
218 call main_bsp - BOOT_OFFSET # never returns
219
220 cli
221 hlt
222
223.global map_kernel
224map_kernel:
225 #
226 # Here we setup mapping for both the unmapped and mapped sections of the kernel.
227 # For simplicity, we map the entire 4G space.
228 #
229 movl %cr4, %ecx
230 orl $(1<<4), %ecx
231 movl %ecx, %cr4 # turn PSE on
232
233 movl $(page_directory+0), %esi
234 movl $(page_directory+2048), %edi
235 xorl %ecx, %ecx
236 xorl %ebx, %ebx
2370:
238 movl $((1<<7)|(1<<0)), %eax
239 orl %ebx, %eax
240 movl %eax, (%esi,%ecx,4) # mapping 0x00000000+%ecx*4M => 0x00000000+%ecx*4M
241 movl %eax, (%edi,%ecx,4) # mapping 0x80000000+%ecx*4M => 0x00000000+%ecx*4M
242 addl $(4*1024*1024), %ebx
243
244 incl %ecx
245 cmpl $512, %ecx
246 jl 0b
247
248 movl %esi, %cr3
249
250 # turn paging on
251 movl %cr0, %ebx
252 orl $(1<<31), %ebx
253 movl %ebx, %cr0
254 ret
255
256
257.section K_DATA_START, "aw", @progbits
258
259.align 4096
260page_directory:
261 .space 4096, 0
262
263.global real_bootstrap_gdtr_boot
264real_bootstrap_gdtr_boot:
265 .word selector(GDT_ITEMS)
266 .long KA2PA(gdt)-BOOT_OFFSET
267
Note: See TracBrowser for help on using the repository browser.