source: mainline/arch/ia32/_link.ld.in@ 69a03b9

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 69a03b9 was 8ccec3c1, checked in by Martin Decky <martin@…>, 20 years ago

remove deprecated pre-grub stuff on ia32
prepare for the same on amd64

  • Property mode set to 100644
File size: 1.8 KB
Line 
1/** IA-32 linker script
2 *
3 * umapped section:
4 * kernel text
5 * kernel data
6 * mapped section:
7 * kernel text
8 * kernel data
9 */
10
11#define __ASM__
12#include <arch/boot/boot.h>
13#include <arch/mm/page.h>
14
15SECTIONS {
16 .unmapped BOOTSTRAP_OFFSET: AT (BOOTSTRAP_OFFSET) {
17 unmapped_ktext_start = .;
18 *(K_TEXT_START);
19 *(K_TEXT_START_2);
20 unmapped_ktext_end = .;
21
22 unmapped_kdata_start = .;
23 *(K_DATA_START);
24 unmapped_kdata_end = .;
25 }
26
27 .mapped (PA2KA(BOOT_OFFSET+BOOTSTRAP_OFFSET)+SIZEOF(.unmapped)): AT (BOOTSTRAP_OFFSET+SIZEOF(.unmapped)) {
28 ktext_start = .;
29 *(.text);
30 ktext_end = .;
31
32 kdata_start = .;
33 *(.data); /* initialized data */
34 *(.rodata*); /* string literals */
35 *(COMMON); /* global variables */
36 hardcoded_load_address = .;
37 LONG(PA2KA(BOOT_OFFSET+BOOTSTRAP_OFFSET));
38 hardcoded_ktext_size = .;
39 LONG((ktext_end - ktext_start) + (unmapped_ktext_end - unmapped_ktext_start));
40 hardcoded_kdata_size = .;
41 LONG((kdata_end - kdata_start) + (unmapped_kdata_end - unmapped_kdata_start));
42 hardcoded_unmapped_ktext_size = .;
43 LONG(unmapped_ktext_end - unmapped_ktext_start);
44 hardcoded_unmapped_kdata_size = .;
45 LONG(unmapped_kdata_end - unmapped_kdata_start);
46 symbol_table = .;
47 *(symtab.*); /* Symbol table, must be LAST symbol! */
48 *(.bss); /* uninitialized static variables */
49 kdata_end = .;
50 }
51
52 /DISCARD/ : {
53 *(.note.GNU-stack);
54 *(.comment);
55 }
56
57
58 _hardcoded_kernel_size = (ktext_end - ktext_start) + (unmapped_ktext_end - unmapped_ktext_start) + (kdata_end - kdata_start) + (unmapped_kdata_end - unmapped_kdata_start);
59 _hardcoded_unmapped_size = (unmapped_ktext_end - unmapped_ktext_start) + (unmapped_kdata_end - unmapped_kdata_start);
60
61 e820table_boot = KA2PA(e820table) - BOOT_OFFSET;
62 e820counter_boot = KA2PA(e820counter) - BOOT_OFFSET;
63 real_bootstrap_gdtr = PA2KA(real_bootstrap_gdtr_boot);
64}
Note: See TracBrowser for help on using the repository browser.