source: mainline/arch/ia32/_link.ld.in@ 39cea6a

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 39cea6a was 66def8d, checked in by Martin Decky <martin@…>, 20 years ago

simplify and cleanup ia32 boot process, remove obsolete stuff
  • Property mode set to 100644
File size: 1.6 KB
Line 
1/** IA-32 linker script
2 *
3 * umapped section:
4 * kernel text
5 * kernel data
6 * mapped section:
7 * kernel text
8 * kernel data
9 */
10
11#define __ASM__
12#include <arch/boot/boot.h>
13#include <arch/mm/page.h>
14
15SECTIONS {
16 .unmapped BOOT_OFFSET: AT (0) {
17 unmapped_ktext_start = .;
18 *(K_TEXT_START);
19 unmapped_ktext_end = .;
20
21 unmapped_kdata_start = .;
22 *(K_DATA_START);
23 unmapped_kdata_end = .;
24 }
25
26 .mapped (PA2KA(BOOT_OFFSET)+SIZEOF(.unmapped)): AT (SIZEOF(.unmapped)) {
27 ktext_start = .;
28 *(.text);
29 ktext_end = .;
30
31 kdata_start = .;
32 *(.data); /* initialized data */
33 *(.rodata*); /* string literals */
34 *(COMMON); /* global variables */
35 hardcoded_load_address = .;
36 LONG(PA2KA(BOOT_OFFSET));
37 hardcoded_ktext_size = .;
38 LONG((ktext_end - ktext_start) + (unmapped_ktext_end - unmapped_ktext_start));
39 hardcoded_kdata_size = .;
40 LONG((kdata_end - kdata_start) + (unmapped_kdata_end - unmapped_kdata_start));
41 hardcoded_unmapped_ktext_size = .;
42 LONG(unmapped_ktext_end - unmapped_ktext_start);
43 hardcoded_unmapped_kdata_size = .;
44 LONG(unmapped_kdata_end - unmapped_kdata_start);
45 symbol_table = .;
46 *(symtab.*); /* Symbol table, must be LAST symbol! */
47 *(.bss); /* uninitialized static variables */
48 kdata_end = .;
49 }
50
51 /DISCARD/ : {
52 *(.note.GNU-stack);
53 *(.comment);
54 }
55
56#ifdef CONFIG_SMP
57
58 _hardcoded_unmapped_size = (unmapped_ktext_end - unmapped_ktext_start) + (unmapped_kdata_end - unmapped_kdata_start);
59 ap_boot = unmapped_ap_boot - BOOT_OFFSET + AP_BOOT_OFFSET;
60 ap_gdtr = unmapped_ap_gdtr - BOOT_OFFSET + AP_BOOT_OFFSET;
61 protected_ap_gdtr = PA2KA(ap_gdtr);
62
63#endif /* CONFIG_SMP */
64
65}
Note: See TracBrowser for help on using the repository browser.