source: mainline/arch/amd64/src/boot/boot.S@ 42744880

lfn serial ticket/834-toolchain-update topic/msim-upgrade topic/simplify-dev-export
Last change on this file since 42744880 was 42744880, checked in by Jakub Jermar <jakub@…>, 20 years ago

Convert size_t, count_t and index_t to 64-bits on 64-bit architectures.
Change some pfn_t usages to count_t, size_t and index_t.
  • Property mode set to 100644
File size: 8.4 KB
Line 
1#
2# Copyright (C) 2005 Ondrej Palkovsky
3# Copyright (C) 2006 Martin Decky
4# All rights reserved.
5#
6# Redistribution and use in source and binary forms, with or without
7# modification, are permitted provided that the following conditions
8# are met:
9#
10# - Redistributions of source code must retain the above copyright
11# notice, this list of conditions and the following disclaimer.
12# - Redistributions in binary form must reproduce the above copyright
13# notice, this list of conditions and the following disclaimer in the
14# documentation and/or other materials provided with the distribution.
15# - The name of the author may not be used to endorse or promote products
16# derived from this software without specific prior written permission.
17#
18# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28#
29
30#include <arch/boot/boot.h>
31#include <arch/boot/memmap.h>
32#include <arch/mm/page.h>
33#include <arch/mm/ptl.h>
34#include <arch/pm.h>
35#include <arch/cpu.h>
36#include <arch/cpuid.h>
37
38#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
39
40.section K_TEXT_START, "ax"
41
42.code32
43.align 4
44.global multiboot_image_start
45multiboot_header:
46 .long MULTIBOOT_HEADER_MAGIC
47 .long MULTIBOOT_HEADER_FLAGS
48 .long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
49 .long multiboot_header
50 .long unmapped_ktext_start
51 .long 0
52 .long 0
53 .long multiboot_image_start
54
55multiboot_image_start:
56 movl $START_STACK, %esp # initialize stack pointer
57 lgdt bootstrap_gdtr # initialize Global Descriptor Table register
58
59 movw $gdtselector(KDATA_DES), %cx
60 movw %cx, %es
61 movw %cx, %ds # kernel data + stack
62 movw %cx, %ss
63 # Simics seems to remove hidden part of GS on entering user mode
64 # when _visible_ part of GS does not point to user-mode segment
65 movw $gdtselector(UDATA_DES), %cx
66 movw %cx, %fs
67 movw %cx, %gs
68
69 jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
70 multiboot_meeting_point:
71
72 movl %eax, grub_eax # save parameters from GRUB
73 movl %ebx, grub_ebx
74
75 # Protected 32-bit. We want to reuse the code-seg descriptor,
76 # the Default operand size must not be 1 when entering long mode
77
78 movl $0x80000000, %eax
79 cpuid
80 cmp $0x80000000, %eax # any function > 80000000h?
81 jbe long_mode_unsupported
82 movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001
83 cpuid
84 bt $29, %edx # Test if long mode is supported.
85 jc long_mode_supported
86
87 long_mode_unsupported:
88 cli
89 hlt
90
91 long_mode_supported:
92
93 # Enable 64-bit page transaltion entries - CR4.PAE = 1.
94 # Paging is not enabled until after long mode is enabled
95
96 movl %cr4, %eax
97 btsl $5, %eax
98 movl %eax, %cr4
99
100 # Set up paging tables
101
102 leal ptl_0, %eax
103 movl %eax, %cr3
104
105 # Enable long mode
106
107 movl $EFER_MSR_NUM, %ecx # EFER MSR number
108 rdmsr # Read EFER
109 btsl $AMD_LME_FLAG, %eax # Set LME=1
110 wrmsr # Write EFER
111
112 # Enable paging to activate long mode (set CR0.PG=1)
113
114 movl %cr0, %eax
115 btsl $31, %eax
116 movl %eax, %cr0
117
118 # At this point we are in compatibility mode
119
120 jmpl $gdtselector(KTEXT_DES), $start64
121
122.code64
123start64:
124 movq $(PA2KA(START_STACK)), %rsp
125 movl grub_eax, %eax
126 movl grub_ebx, %ebx
127
128 cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
129 je valid_boot
130
131 xorl %ecx, %ecx # no memory size or map available
132 movl %ecx, e801memorysize
133 movl %ecx, e820counter
134
135 jmp invalid_boot
136
137 valid_boot:
138
139 movl (%ebx), %eax # ebx = physical address of struct multiboot_info
140
141 bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
142 jc mem_valid
143
144 xorl %ecx, %ecx
145 jmp mem_invalid
146
147 mem_valid:
148 movl 4(%ebx), %ecx # mbi->mem_lower
149 addl 8(%ebx), %ecx # mbi->mem_upper
150
151 mem_invalid:
152 movl %ecx, e801memorysize
153
154 bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
155 jc mods_valid
156
157 xorl %ecx, %ecx
158 xorl %edx, %edx
159 jmp mods_invalid
160
161 mods_valid:
162 movl 20(%ebx), %ecx # mbi->mods_count
163 cmpl $0, %ecx
164 je mods_invalid
165
166 xorq %rdx, %rdx
167 movq %rdx, %rcx
168 movl 24(%ebx), %esi # mbi->mods_addr
169 movl 0(%esi), %edx # mods->mod_start
170 movl 4(%esi), %ecx # mods->mod_end
171 subl %edx, %ecx
172 addq $0xffffffff80000000, %rdx
173
174 mods_invalid:
175 movq %rcx, init_size
176 movq %rdx, init_addr
177
178 bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
179 jc mmap_valid
180
181 xorl %edx, %edx
182 jmp mmap_invalid
183
184 mmap_valid:
185 movl 44(%ebx), %ecx # mbi->mmap_length
186 movl 48(%ebx), %esi # mbi->mmap_addr
187 movq $e820table, %rdi
188 xorl %edx, %edx
189
190 mmap_loop:
191 cmpl $0, %ecx
192 jle mmap_end
193
194 movl 4(%esi), %eax # mmap->base_addr_low
195 movl %eax, (%rdi)
196
197 movl 8(%esi), %eax # mmap->base_addr_high
198 movl %eax, 4(%rdi)
199
200 movl 12(%esi), %eax # mmap->length_low
201 movl %eax, 8(%rdi)
202
203 movl 16(%esi), %eax # mmap->length_high
204 movl %eax, 12(%rdi)
205
206 movl 20(%esi), %eax # mmap->type
207 movl %eax, 16(%rdi)
208
209 movl (%esi), %eax # mmap->size
210 addl $0x4, %eax
211 addl %eax, %esi
212 subl %eax, %ecx
213 addq $MEMMAP_E820_RECORD_SIZE, %rdi
214 incl %edx
215 jmp mmap_loop
216
217 mmap_end:
218
219 mmap_invalid:
220 movl %edx, e820counter
221
222 invalid_boot:
223
224#ifdef CONFIG_SMP
225
226 # copy AP bootstrap routines below 1 MB
227
228 movq $BOOT_OFFSET, %rsi
229 movq $AP_BOOT_OFFSET, %rdi
230 movq $_hardcoded_unmapped_size, %rcx
231 cld
232 rep movsb
233
234#endif
235
236 call main_bsp # never returns
237
238 cli
239 hlt
240
241.section K_DATA_START, "aw", @progbits
242.align 4096
243
244# Identical mapping of first 64MB and the same of -2GB -> 0
245.global ptl_2
246ptl_2:
247 .quad 0x0 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
248 .quad 0x200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
249 .quad 0x400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
250 .quad 0x600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
251 .quad 0x800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
252 .quad 0xa00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
253 .quad 0xc00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
254 .quad 0xe00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
255 .quad 0x1000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
256 .quad 0x1200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
257 .quad 0x1400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
258 .quad 0x1600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
259 .quad 0x1800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
260 .quad 0x1a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
261 .quad 0x1c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
262 .quad 0x1e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
263 .quad 0x2000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
264 .quad 0x2200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
265 .quad 0x2400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
266 .quad 0x2600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
267 .quad 0x2800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
268 .quad 0x2a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
269 .quad 0x2c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
270 .quad 0x2e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
271 .quad 0x3000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
272 .quad 0x3200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
273 .quad 0x3400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
274 .quad 0x3600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
275 .quad 0x3800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
276 .quad 0x3a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
277 .quad 0x3c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
278 .quad 0x3e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
279
280.align 4096
281.global ptl_1
282ptl_1:
283 .quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
284 .fill 509,8,0
285 .quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
286 .fill 1,8,0
287
288.align 4096
289.global ptl_0
290ptl_0:
291 .quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
292 .fill 510,8,0
293 .quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
294
295.global bootstrap_gdtr
296bootstrap_gdtr:
297 .word gdtselector(GDT_ITEMS)
298 .long KA2PA(gdt)
299
300grub_eax:
301 .long 0
302
303grub_ebx:
304 .long 0
Note: See TracBrowser for help on using the repository browser.